os-specific/windows: Add new package cygwinSetup.

This is primarily going to be used for vmTools.runInWindowsVM, but in
theory, it could also work with Nix on CygWin which I haven't tested.

Signed-off-by: aszlig <aszlig@redmoonstudios.org>
This commit is contained in:
aszlig 2014-03-03 22:47:05 +01:00
parent 40635ed343
commit 1771e07e20
No known key found for this signature in database
GPG Key ID: D0EBD0EC8C2DC961
2 changed files with 49 additions and 0 deletions

View File

@ -0,0 +1,47 @@
{ stdenv, fetchcvs, autoconf, automake, libtool, flex, bison, pkgconfig
, zlib, bzip2, lzma, libgcrypt_1_6
}:
with stdenv.lib;
stdenv.mkDerivation rec {
name = "cygwin-setup-${version}";
version = "20131101";
src = fetchcvs {
cvsRoot = ":pserver:anoncvs@cygwin.com:/cvs/cygwin-apps";
module = "setup";
date = version;
sha256 = "024wxaaxkf7p1i78bh5xrsqmfz7ss2amigbfl2r5w9h87zqn9aq3";
};
nativeBuildInputs = [ autoconf automake libtool flex bison pkgconfig ];
buildInputs = let
mkStatic = flip overrideDerivation (o: {
dontDisableStatic = true;
configureFlags = toList (o.configureFlags or []) ++ [ "--enable-static" ];
buildInputs = map mkStatic (o.buildInputs or []);
propagatedBuildInputs = map mkStatic (o.propagatedBuildInputs or []);
});
in map mkStatic [ zlib bzip2 lzma libgcrypt_1_6 ];
configureFlags = "--disable-shared";
dontDisableStatic = true;
preConfigure = ''
autoreconf -vfi
'';
installPhase = ''
install -vD setup.exe "$out/bin/setup.exe"
'';
meta = {
homepage = https://sourceware.org/cygwin-apps/setup.html;
description = "A tool for installing Cygwin";
license = licenses.gpl2Plus;
platforms = platforms.cygwin;
};
}

View File

@ -7170,6 +7170,8 @@ let
};
windows = rec {
cygwinSetup = callPackage ../os-specific/windows/cygwin-setup { };
jom = callPackage ../os-specific/windows/jom { };
w32api = callPackage ../os-specific/windows/w32api {