From 1771e07e205710ecd9c284d582eaa45ccfbbfa77 Mon Sep 17 00:00:00 2001
From: aszlig <aszlig@redmoonstudios.org>
Date: Mon, 3 Mar 2014 22:47:05 +0100
Subject: [PATCH] os-specific/windows: Add new package cygwinSetup.

This is primarily going to be used for vmTools.runInWindowsVM, but in
theory, it could also work with Nix on CygWin which I haven't tested.

Signed-off-by: aszlig <aszlig@redmoonstudios.org>
---
 .../windows/cygwin-setup/default.nix          | 47 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 49 insertions(+)
 create mode 100644 pkgs/os-specific/windows/cygwin-setup/default.nix

diff --git a/pkgs/os-specific/windows/cygwin-setup/default.nix b/pkgs/os-specific/windows/cygwin-setup/default.nix
new file mode 100644
index 00000000000..9f765a4cf0a
--- /dev/null
+++ b/pkgs/os-specific/windows/cygwin-setup/default.nix
@@ -0,0 +1,47 @@
+{ stdenv, fetchcvs, autoconf, automake, libtool, flex, bison, pkgconfig
+, zlib, bzip2, lzma, libgcrypt_1_6
+}:
+
+with stdenv.lib;
+
+stdenv.mkDerivation rec {
+  name = "cygwin-setup-${version}";
+  version = "20131101";
+
+  src = fetchcvs {
+    cvsRoot = ":pserver:anoncvs@cygwin.com:/cvs/cygwin-apps";
+    module = "setup";
+    date = version;
+    sha256 = "024wxaaxkf7p1i78bh5xrsqmfz7ss2amigbfl2r5w9h87zqn9aq3";
+  };
+
+  nativeBuildInputs = [ autoconf automake libtool flex bison pkgconfig ];
+
+  buildInputs = let
+    mkStatic = flip overrideDerivation (o: {
+      dontDisableStatic = true;
+      configureFlags = toList (o.configureFlags or []) ++ [ "--enable-static" ];
+      buildInputs = map mkStatic (o.buildInputs or []);
+      propagatedBuildInputs = map mkStatic (o.propagatedBuildInputs or []);
+    });
+  in map mkStatic [ zlib bzip2 lzma libgcrypt_1_6 ];
+
+  configureFlags = "--disable-shared";
+
+  dontDisableStatic = true;
+
+  preConfigure = ''
+    autoreconf -vfi
+  '';
+
+  installPhase = ''
+    install -vD setup.exe "$out/bin/setup.exe"
+  '';
+
+  meta = {
+    homepage = https://sourceware.org/cygwin-apps/setup.html;
+    description = "A tool for installing Cygwin";
+    license = licenses.gpl2Plus;
+    platforms = platforms.cygwin;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 12b0bc5e4f8..6cd584e6f1f 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -7170,6 +7170,8 @@ let
   };
 
   windows = rec {
+    cygwinSetup = callPackage ../os-specific/windows/cygwin-setup { };
+
     jom = callPackage ../os-specific/windows/jom { };
 
     w32api = callPackage ../os-specific/windows/w32api {