0e333688ce
The major changes are:
* The evaluation is now driven by the declared options. In
particular, this fixes the long-standing problem with lack of
laziness of disabled option definitions. Thus, a configuration like
config = mkIf false {
environment.systemPackages = throw "bla";
};
will now evaluate without throwing an error. This also improves
performance since we're not evaluating unused option definitions.
* The implementation of properties is greatly simplified.
* There is a new type constructor "submodule" that replaces
"optionSet". Unlike "optionSet", "submodule" gets its option
declarations as an argument, making it more like "listOf" and other
type constructors. A typical use is:
foo = mkOption {
type = type.attrsOf (type.submodule (
{ config, ... }:
{ bar = mkOption { ... };
xyzzy = mkOption { ... };
}));
};
Existing uses of "optionSet" are automatically mapped to
"submodule".
* Modules are now checked for unsupported attributes: you get an error
if a module contains an attribute other than "config", "options" or
"imports".
* The new implementation is faster and uses much less memory.
65 lines
2.3 KiB
Nix
65 lines
2.3 KiB
Nix
# From an end-user configuration file (`configuration'), build a NixOS
|
|
# configuration object (`config') from which we can retrieve option
|
|
# values.
|
|
|
|
{ system ? builtins.currentSystem
|
|
, pkgs ? null
|
|
, baseModules ? import ../modules/module-list.nix
|
|
, extraArgs ? {}
|
|
, modules
|
|
}:
|
|
|
|
let extraArgs_ = extraArgs; pkgs_ = pkgs; system_ = system; in
|
|
|
|
rec {
|
|
|
|
# These are the NixOS modules that constitute the system configuration.
|
|
configComponents = modules ++ baseModules;
|
|
|
|
# Merge the option definitions in all modules, forming the full
|
|
# system configuration. It's not checked for undeclared options.
|
|
systemModule =
|
|
pkgs.lib.evalModules configComponents extraArgs;
|
|
|
|
config = systemModule.config;
|
|
|
|
# These are the extra arguments passed to every module. In
|
|
# particular, Nixpkgs is passed through the "pkgs" argument.
|
|
extraArgs = extraArgs_ // {
|
|
inherit pkgs modules baseModules;
|
|
modulesPath = ../modules;
|
|
pkgs_i686 = import ./nixpkgs.nix { system = "i686-linux"; };
|
|
utils = import ./utils.nix pkgs;
|
|
};
|
|
|
|
# Import Nixpkgs, allowing the NixOS option nixpkgs.config to
|
|
# specify the Nixpkgs configuration (e.g., to set package options
|
|
# such as firefox.enableGeckoMediaPlayer, or to apply global
|
|
# overrides such as changing GCC throughout the system), and the
|
|
# option nixpkgs.system to override the platform type. This is
|
|
# tricky, because we have to prevent an infinite recursion: "pkgs"
|
|
# is passed as an argument to NixOS modules, but the value of "pkgs"
|
|
# depends on config.nixpkgs.config, which we get from the modules.
|
|
# So we call ourselves here with "pkgs" explicitly set to an
|
|
# instance that doesn't depend on nixpkgs.config.
|
|
pkgs =
|
|
if pkgs_ != null
|
|
then pkgs_
|
|
else import ./nixpkgs.nix (
|
|
let
|
|
system = if nixpkgsOptions.system != "" then nixpkgsOptions.system else system_;
|
|
nixpkgsOptions = (import ./eval-config.nix {
|
|
inherit system extraArgs modules;
|
|
# For efficiency, leave out most NixOS modules; they don't
|
|
# define nixpkgs.config, so it's pointless to evaluate them.
|
|
baseModules = [ ../modules/misc/nixpkgs.nix ];
|
|
pkgs = import ./nixpkgs.nix { system = system_; config = {}; };
|
|
}).config.nixpkgs;
|
|
in
|
|
{
|
|
inherit system;
|
|
inherit (nixpkgsOptions) config;
|
|
});
|
|
|
|
}
|