f729f12e4e
* Moved some scriptlets to the appropriate modules. * Put the scriptlet that sets the default path at the start, since it never makes sense not to have it there. It no longer needs to be declared as a dependency. * If a scriptlet has no dependencies, it can be denoted as a plain string (i.e., `noDepEntry' is not needed anymore). svn path=/nixos/trunk/; revision=23762
75 lines
1.7 KiB
Nix
75 lines
1.7 KiB
Nix
{ config, pkgs, ... }:
|
|
|
|
with pkgs.lib;
|
|
|
|
let
|
|
|
|
inherit (pkgs) mysql gzip;
|
|
|
|
location = config.services.mysqlBackup.location ;
|
|
|
|
mysqlBackupCron = db : ''
|
|
${config.services.mysqlBackup.period} ${config.services.mysqlBackup.user} ${mysql}/bin/mysqldump ${db} | ${gzip}/bin/gzip -c > ${location}/${db}.gz
|
|
'';
|
|
|
|
in
|
|
|
|
{
|
|
options = {
|
|
|
|
services.mysqlBackup = {
|
|
|
|
enable = mkOption {
|
|
default = false;
|
|
description = ''
|
|
Whether to enable MySQL backups.
|
|
'';
|
|
};
|
|
|
|
period = mkOption {
|
|
default = "15 01 * * *";
|
|
description = ''
|
|
This option defines (in the format used by cron) when the
|
|
databases should be dumped.
|
|
The default is to update at 01:15 (at night) every day.
|
|
'';
|
|
};
|
|
|
|
user = mkOption {
|
|
default = "mysql";
|
|
description = ''
|
|
User to be used to perform backup.
|
|
'';
|
|
};
|
|
|
|
databases = mkOption {
|
|
default = [];
|
|
description = ''
|
|
List of database names to dump.
|
|
'';
|
|
};
|
|
|
|
location = mkOption {
|
|
default = "/var/backup/mysql";
|
|
description = ''
|
|
Location to put the gzipped MySQL database dumps.
|
|
'';
|
|
};
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf config.services.mysqlBackup.enable {
|
|
|
|
services.cron.systemCronJobs = map mysqlBackupCron config.services.mysqlBackup.databases;
|
|
|
|
system.activationScripts.mysqlBackup = stringAfter [ "stdio" "defaultPath" "systemConfig" "users" ]
|
|
''
|
|
mkdir -m 0700 -p ${config.services.mysqlBackup.location}
|
|
chown ${config.services.mysqlBackup.user} ${config.services.mysqlBackup.location}
|
|
'';
|
|
|
|
};
|
|
|
|
}
|