7869d16545
Also begin to start work on cross compilation, though that will have to be finished later. The patches are based on the first version of https://reviews.llvm.org/D99484. It's very annoying to do the back-porting but the review has uncovered nothing super major so I'm fine sticking with what I've got. Beyond making the outputs work, I also strove to re-sync the packages, as they have been drifting pointlessly apart for some time. ---- Other misc notes, highly incomplete - lvm-config-native and llvm-config are put in `dev` because they are tools just for build time. - Clang no longer has an lld dep. That was introduced in db29857eb391ed002046090851a44c452b80bdbd, but if clang needs help finding lld when it is used we should just pass it flags / put in the resource dir. Providing it at build time increases critical path length for no good reason. ---- A note on `nativeCC`: `stdenv` takes tools from the previous stage, so: 1. `pkgsBuildBuild`: `(?1, x, x)` 2. `pkgsBuildBuild.stdenv.cc`: `(?0, ?1, x)` while: 1. `pkgsBuildBuild`: `(?1, x, x)` 2. `pkgsBuildBuild.targetPackages`: `(x, x, ?2)` 3. `pkgsBuildBuild.targetPackages.stdenv.cc`: `(?1, x, x)`
58 lines
1.9 KiB
Nix
58 lines
1.9 KiB
Nix
{ lib, stdenv, cmake, fetch, libcxx, libunwind, llvm, version }:
|
|
|
|
stdenv.mkDerivation {
|
|
pname = "libc++abi";
|
|
inherit version;
|
|
|
|
src = fetch "libcxxabi" "12lp799rskr4fc2xr64qn4jfkjnfd8b1aymvsxyn4k9ar7r9pgqv";
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
postUnpack = ''
|
|
unpackFile ${libcxx.src}
|
|
unpackFile ${llvm.src}
|
|
export cmakeFlags="-DLLVM_PATH=$PWD/$(ls -d llvm-*) -DLIBCXXABI_LIBCXX_PATH=$PWD/$(ls -d libcxx-*)"
|
|
'' + lib.optionalString stdenv.isDarwin ''
|
|
export TRIPLE=x86_64-apple-darwin
|
|
'' + lib.optionalString stdenv.hostPlatform.isMusl ''
|
|
patch -p1 -d $(ls -d libcxx-*) -i ${../../libcxx-0001-musl-hacks.patch}
|
|
'';
|
|
|
|
patches = [
|
|
./gnu-install-dirs.patch
|
|
];
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
buildInputs = lib.optional (!stdenv.isDarwin && !stdenv.isFreeBSD) libunwind;
|
|
|
|
installPhase = if stdenv.isDarwin
|
|
then ''
|
|
for file in lib/*.dylib; do
|
|
# this should be done in CMake, but having trouble figuring out
|
|
# the magic combination of necessary CMake variables
|
|
# if you fancy a try, take a look at
|
|
# https://gitlab.kitware.com/cmake/community/-/wikis/doc/cmake/RPATH-handling
|
|
install_name_tool -id $out/$file $file
|
|
done
|
|
make install
|
|
install -d 755 $out/include
|
|
install -m 644 ../include/*.h $out/include
|
|
''
|
|
else ''
|
|
install -d -m 755 $out/include $out/lib
|
|
install -m 644 lib/libc++abi.a $out/lib
|
|
install -m 644 lib/libc++abi.so.1.0 $out/lib
|
|
install -m 644 ../include/cxxabi.h $out/include
|
|
ln -s libc++abi.so.1.0 $out/lib/libc++abi.so
|
|
ln -s libc++abi.so.1.0 $out/lib/libc++abi.so.1
|
|
'';
|
|
|
|
meta = {
|
|
homepage = "https://libcxxabi.llvm.org/";
|
|
description = "A new implementation of low level support for a standard C++ library";
|
|
license = with lib.licenses; [ ncsa mit ];
|
|
maintainers = with lib.maintainers; [ vlstill ];
|
|
platforms = lib.platforms.unix;
|
|
};
|
|
}
|