7869d16545
Also begin to start work on cross compilation, though that will have to be finished later. The patches are based on the first version of https://reviews.llvm.org/D99484. It's very annoying to do the back-porting but the review has uncovered nothing super major so I'm fine sticking with what I've got. Beyond making the outputs work, I also strove to re-sync the packages, as they have been drifting pointlessly apart for some time. ---- Other misc notes, highly incomplete - lvm-config-native and llvm-config are put in `dev` because they are tools just for build time. - Clang no longer has an lld dep. That was introduced in db29857eb391ed002046090851a44c452b80bdbd, but if clang needs help finding lld when it is used we should just pass it flags / put in the resource dir. Providing it at build time increases critical path length for no good reason. ---- A note on `nativeCC`: `stdenv` takes tools from the previous stage, so: 1. `pkgsBuildBuild`: `(?1, x, x)` 2. `pkgsBuildBuild.stdenv.cc`: `(?0, ?1, x)` while: 1. `pkgsBuildBuild`: `(?1, x, x)` 2. `pkgsBuildBuild.targetPackages`: `(x, x, ?2)` 3. `pkgsBuildBuild.targetPackages.stdenv.cc`: `(?1, x, x)`
109 lines
2.5 KiB
Nix
109 lines
2.5 KiB
Nix
{ lib, stdenv
|
|
, fetch
|
|
, cmake
|
|
, zlib
|
|
, ncurses
|
|
, swig
|
|
, which
|
|
, libedit
|
|
, libxml2
|
|
, libllvm
|
|
, libclang
|
|
, python3
|
|
, version
|
|
, darwin
|
|
, lit
|
|
, enableManpages ? false
|
|
}:
|
|
|
|
stdenv.mkDerivation (rec {
|
|
pname = "lldb";
|
|
inherit version;
|
|
|
|
src = fetch pname "051p5b04y6z3g730rmc2n2v71lipbw7k69riww3a6sl74myfiaq7";
|
|
|
|
patches = [
|
|
./procfs.patch
|
|
./gnu-install-dirs.patch
|
|
];
|
|
|
|
outputs = [ "out" "lib" "dev" ];
|
|
|
|
nativeBuildInputs = [
|
|
cmake python3 which swig lit
|
|
] ++ lib.optionals enableManpages [
|
|
python3.pkgs.sphinx python3.pkgs.recommonmark
|
|
];
|
|
|
|
buildInputs = [
|
|
ncurses zlib libedit libxml2 libllvm
|
|
] ++ lib.optionals stdenv.isDarwin [
|
|
darwin.libobjc
|
|
darwin.apple_sdk.libs.xpc
|
|
darwin.apple_sdk.frameworks.Foundation
|
|
darwin.bootstrap_cmds
|
|
darwin.apple_sdk.frameworks.Carbon
|
|
darwin.apple_sdk.frameworks.Cocoa
|
|
];
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
cmakeFlags = [
|
|
"-DLLDB_INCLUDE_TESTS=${if doCheck then "YES" else "NO"}"
|
|
"-DLLVM_ENABLE_RTTI=OFF"
|
|
"-DClang_DIR=${libclang.dev}/lib/cmake"
|
|
"-DLLVM_EXTERNAL_LIT=${lit}/bin/lit"
|
|
] ++ lib.optionals stdenv.isDarwin [
|
|
"-DLLDB_USE_SYSTEM_DEBUGSERVER=ON"
|
|
] ++ lib.optionals (!stdenv.isDarwin) [
|
|
"-DLLDB_CODESIGN_IDENTITY=" # codesigning makes nondeterministic
|
|
] ++ lib.optionals enableManpages [
|
|
"-DLLVM_ENABLE_SPHINX=ON"
|
|
"-DSPHINX_OUTPUT_MAN=ON"
|
|
"-DSPHINX_OUTPUT_HTML=OFF"
|
|
] ++ lib.optionals doCheck [
|
|
"-DLLDB_TEST_C_COMPILER=${stdenv.cc}/bin/${stdenv.cc.targetPrefix}cc"
|
|
"-DLLDB_TEST_CXX_COMPILER=${stdenv.cc}/bin/${stdenv.cc.targetPrefix}c++"
|
|
];
|
|
|
|
doCheck = false;
|
|
|
|
postInstall = ''
|
|
# Editor support
|
|
# vscode:
|
|
install -D ../tools/lldb-vscode/package.json $out/share/vscode/extensions/llvm-org.lldb-vscode-0.1.0/package.json
|
|
mkdir -p $out/share/vscode/extensions/llvm-org.lldb-vscode-0.1.0/bin
|
|
ln -s $out/bin/llvm-vscode $out/share/vscode/extensions/llvm-org.lldb-vscode-0.1.0/bin
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A next-generation high-performance debugger";
|
|
homepage = "https://lldb.llvm.org";
|
|
license = licenses.ncsa;
|
|
platforms = platforms.all;
|
|
};
|
|
} // lib.optionalAttrs enableManpages {
|
|
pname = "lldb-manpages";
|
|
|
|
buildPhase = ''
|
|
make docs-man
|
|
'';
|
|
|
|
propagatedBuildInputs = [];
|
|
|
|
# manually install lldb man page
|
|
installPhase = ''
|
|
mkdir -p $out/share/man/man1
|
|
install docs/man/lldb.1 -t $out/share/man/man1/
|
|
'';
|
|
|
|
postPatch = null;
|
|
postInstall = null;
|
|
|
|
outputs = [ "out" ];
|
|
|
|
doCheck = false;
|
|
|
|
meta.description = "man pages for LLDB ${version}";
|
|
})
|