94255ffab5
* chromedriver: add dbus to libraries It is apparently required since version 94. Fixes issue #139547 (cherry picked from commit 433b2bc44487c90c33cb58d87434a287e6d43b15) * chromedriver: remove extraneous LD_LIBRARY_PATH in wrapProgram wrapProgram already prepends passed value to the specified environment variable; no need to specify it explicitly. (cherry picked from commit 38ddfe7f3ff206888806302539def70b80ef427b) * chromedriver: add a package test checking the reported version (cherry picked from commit 1106f4bafc0b444384c171c63ca78b8b6676842e) * Update pkgs/development/tools/selenium/chromedriver/default.nix (cherry picked from commit 852612eac99dc403c0ea09a5daca9b65b5b7e123) Co-authored-by: Ivan Timokhin <nixpkgs@ivan.timokhin.name> Co-authored-by: Sandro <sandro.jaeckel@gmail.com>
72 lines
2.2 KiB
Nix
72 lines
2.2 KiB
Nix
{ lib, stdenv, fetchurl, unzip, makeWrapper
|
|
, cairo, fontconfig, freetype, gdk-pixbuf, glib
|
|
, glibc, gtk2, libX11, nspr, nss, pango, gconf
|
|
, libxcb, libXi, libXrender, libXext, dbus
|
|
, testVersion, chromedriver
|
|
}:
|
|
|
|
let
|
|
upstream-info = (lib.importJSON ../../../../applications/networking/browsers/chromium/upstream-info.json).stable.chromedriver;
|
|
allSpecs = {
|
|
x86_64-linux = {
|
|
system = "linux64";
|
|
sha256 = upstream-info.sha256_linux;
|
|
};
|
|
|
|
x86_64-darwin = {
|
|
system = "mac64";
|
|
sha256 = upstream-info.sha256_darwin;
|
|
};
|
|
};
|
|
|
|
spec = allSpecs.${stdenv.hostPlatform.system}
|
|
or (throw "missing chromedriver binary for ${stdenv.hostPlatform.system}");
|
|
|
|
libs = lib.makeLibraryPath [
|
|
stdenv.cc.cc.lib
|
|
cairo fontconfig freetype
|
|
gdk-pixbuf glib gtk2 gconf
|
|
libX11 nspr nss pango libXrender
|
|
gconf libxcb libXext libXi
|
|
dbus
|
|
];
|
|
|
|
in stdenv.mkDerivation rec {
|
|
pname = "chromedriver";
|
|
version = upstream-info.version;
|
|
|
|
src = fetchurl {
|
|
url = "https://chromedriver.storage.googleapis.com/${version}/chromedriver_${spec.system}.zip";
|
|
sha256 = spec.sha256;
|
|
};
|
|
|
|
nativeBuildInputs = [ unzip makeWrapper ];
|
|
|
|
unpackPhase = "unzip $src";
|
|
|
|
installPhase = ''
|
|
install -m755 -D chromedriver $out/bin/chromedriver
|
|
'' + lib.optionalString (!stdenv.isDarwin) ''
|
|
patchelf --set-interpreter ${glibc.out}/lib/ld-linux-x86-64.so.2 $out/bin/chromedriver
|
|
wrapProgram "$out/bin/chromedriver" --prefix LD_LIBRARY_PATH : "${libs}"
|
|
'';
|
|
|
|
passthru.tests.version = testVersion { package = chromedriver; };
|
|
|
|
meta = with lib; {
|
|
homepage = "https://chromedriver.chromium.org/";
|
|
description = "A WebDriver server for running Selenium tests on Chrome";
|
|
longDescription = ''
|
|
WebDriver is an open source tool for automated testing of webapps across
|
|
many browsers. It provides capabilities for navigating to web pages, user
|
|
input, JavaScript execution, and more. ChromeDriver is a standalone
|
|
server that implements the W3C WebDriver standard.
|
|
'';
|
|
license = licenses.bsd3;
|
|
maintainers = with maintainers; [ goibhniu marsam primeos ];
|
|
# Note from primeos: By updating Chromium I also update Google Chrome and
|
|
# ChromeDriver.
|
|
platforms = attrNames allSpecs;
|
|
};
|
|
}
|