From ff5eae075a6a42994b8ae406afdb4cb64146f4b0 Mon Sep 17 00:00:00 2001
From: Tobias Geerinckx-Rice <tobias.geerinckx.rice@gmail.com>
Date: Thu, 8 Jan 2015 23:38:10 +0100
Subject: [PATCH] Add freefall NixOS service module

---
 nixos/modules/module-list.nix                |  1 +
 nixos/modules/services/hardware/freefall.nix | 62 ++++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 nixos/modules/services/hardware/freefall.nix

diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index 4e0d3b77fe3..cf82e5035d9 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -144,6 +144,7 @@
   ./services/hardware/acpid.nix
   ./services/hardware/amd-hybrid-graphics.nix
   ./services/hardware/bluetooth.nix
+  ./services/hardware/freefall.nix
   ./services/hardware/nvidia-optimus.nix
   ./services/hardware/pcscd.nix
   ./services/hardware/pommed.nix
diff --git a/nixos/modules/services/hardware/freefall.nix b/nixos/modules/services/hardware/freefall.nix
new file mode 100644
index 00000000000..6e6960bac49
--- /dev/null
+++ b/nixos/modules/services/hardware/freefall.nix
@@ -0,0 +1,62 @@
+{ config, lib, pkgs, utils, ... }:
+
+with lib;
+
+{
+
+  ###### interface
+
+  options = with types; {
+
+    services.freefall = {
+
+      enable = mkOption {
+        default = false;
+        description = ''
+          Whether to protect HP/Dell laptop hard drives (not SSDs) in free fall.
+        '';
+        type = bool;
+      };
+
+      devices = mkOption {
+        default = [ "/dev/sda" ];
+        description = ''
+          Device paths to all internal spinning hard drives.
+        '';
+        type = listOf string;
+      };
+
+    };
+
+  };
+
+  ###### implementation
+
+  config = let
+
+    cfg = config.services.freefall;
+
+    mkService = dev:
+      assert dev != "";
+      let dev' = utils.escapeSystemdPath dev; in
+      nameValuePair "freefall-${dev'}"
+        { description = "Free-fall protection for ${dev}";
+        after = [ "${dev'}.device" ];
+        wantedBy = [ "${dev'}.device" ];
+        path = [ pkgs.freefall ];
+        serviceConfig = {
+          ExecStart = "${pkgs.freefall}/bin/freefall ${dev}";
+          Restart = "on-failure";
+          Type = "forking";
+        };
+      };
+
+  in mkIf cfg.enable {
+
+    environment.systemPackages = [ pkgs.freefall ];
+
+    systemd.services = listToAttrs (map mkService cfg.devices);
+
+  };
+
+}