Merge pull request #31488 from adisbladis/awscli

awscli: 1.11.162 -> 1.11.185

pkgs/tools/admin/aws_shell/default.nix

@@ -0,0 +1,42 @@
+{ stdenv
+, buildPythonPackage
+, fetchPypi
+, awscli
+, prompt_toolkit
+, boto3
+, configobj
+, pygments
+}:
+
+buildPythonPackage rec {
+  pname = "aws-shell";
+  version = "0.1.1";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "1pw9lrdjl24n6lrs6lnqpyiyic8bdxgvhyqvb2rx6kkbjrfhhgv5";
+  };
+
+  # Why does it propagate packages that are used for testing?
+  propagatedBuildInputs = [
+    awscli
+    prompt_toolkit
+    boto3
+    configobj
+    pygments
+  ];
+
+  #Checks are failing due to missing TTY, which won't exist.
+  doCheck = false;
+  preCheck = ''
+    mkdir -p check-phase
+    export HOME=$(pwd)/check-phase
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = https://github.com/awslabs/aws-shell;
+    description = "An integrated shell for working with the AWS CLI";
+    license = licenses.asl20;
+    maintainers = [ ];
+  };
+}

pkgs/tools/admin/awscli/default.nix

@@ -0,0 +1,68 @@
+{ stdenv
+, buildPythonPackage
+, fetchPypi
+, botocore
+, bcdoc
+, s3transfer
+, six
+, colorama
+, docutils
+, rsa
+, pyyaml
+, groff
+, less
+}:
+
+let
+  colorama_3_7 = colorama.overrideAttrs (old: rec {
+    name = "${pname}-${version}";
+    pname = "colorama";
+    version = "0.3.7";
+    src = fetchPypi {
+      inherit pname version;
+      sha256 = "0avqkn6362v7k2kg3afb35g4sfdvixjgy890clip4q174p9whhz0";
+    };
+  });
+
+in buildPythonPackage rec {
+  name = "${pname}-${version}";
+  pname = "awscli";
+  version = "1.11.185";
+  namePrefix = "";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "18rskl6sla456z4hkq2gmmm03fqc4rqw5pfiqdyc7a2v9kljv4ah";
+  };
+
+  # No tests included
+  doCheck = false;
+
+  propagatedBuildInputs = [
+    botocore
+    bcdoc
+    s3transfer
+    six
+    colorama_3_7
+    docutils
+    rsa
+    pyyaml
+    groff
+    less
+  ];
+
+  postInstall = ''
+    mkdir -p $out/etc/bash_completion.d
+    echo "complete -C $out/bin/aws_completer aws" > $out/etc/bash_completion.d/awscli
+    mkdir -p $out/share/zsh/site-functions
+    mv $out/bin/aws_zsh_completer.sh $out/share/zsh/site-functions
+    rm $out/bin/aws.cmd
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = https://aws.amazon.com/cli/;
+    description = "Unified tool to manage your AWS services";
+    license = stdenv.lib.licenses.asl20;
+    maintainers = with maintainers; [ muflax ];
+  };
+}