From ea3bdfcebe8a9f2bc2e1629d0c691e699028d841 Mon Sep 17 00:00:00 2001
From: Lancelot SIX <lsix@lancelotsix.com>
Date: Thu, 7 Jan 2021 20:51:44 +0000
Subject: [PATCH] readline81: init at 8.1p0

See https://lists.gnu.org/archive/html/info-gnu/2020-12/msg00002.html
for release information
---
 pkgs/development/libraries/readline/8.1.nix   | 62 +++++++++++++++++++
 .../readline/readline-8.1-patches.nix         |  4 ++
 pkgs/top-level/all-packages.nix               |  2 +
 3 files changed, 68 insertions(+)
 create mode 100644 pkgs/development/libraries/readline/8.1.nix
 create mode 100644 pkgs/development/libraries/readline/readline-8.1-patches.nix

diff --git a/pkgs/development/libraries/readline/8.1.nix b/pkgs/development/libraries/readline/8.1.nix
new file mode 100644
index 00000000000..35835c1a143
--- /dev/null
+++ b/pkgs/development/libraries/readline/8.1.nix
@@ -0,0 +1,62 @@
+{ fetchurl, stdenv, lib, ncurses
+}:
+
+stdenv.mkDerivation rec {
+  pname = "readline";
+  version = "8.1p${toString (builtins.length upstreamPatches)}";
+
+  src = fetchurl {
+    url = "mirror://gnu/readline/readline-${meta.branch}.tar.gz";
+    sha256 = "00ibp0n9crbwx15k9vvckq5wsipw98b1px8pd8i34chy2gpb9kpq";
+  };
+
+  outputs = [ "out" "dev" "man" "doc" "info" ];
+
+  propagatedBuildInputs = [ncurses];
+
+  patchFlags = [ "-p0" ];
+
+  upstreamPatches =
+    (let
+       patch = nr: sha256:
+         fetchurl {
+           url = "mirror://gnu/readline/readline-${meta.branch}-patches/readline81-${nr}";
+           inherit sha256;
+         };
+     in
+       import ./readline-8.1-patches.nix patch);
+
+  patches =
+    [ ./link-against-ncurses.patch
+      ./no-arch_only-6.3.patch
+    ]
+    ++ upstreamPatches;
+
+  meta = with lib; {
+    description = "Library for interactive line editing";
+
+    longDescription = ''
+      The GNU Readline library provides a set of functions for use by
+      applications that allow users to edit command lines as they are
+      typed in.  Both Emacs and vi editing modes are available.  The
+      Readline library includes additional functions to maintain a
+      list of previously-entered command lines, to recall and perhaps
+      reedit those lines, and perform csh-like history expansion on
+      previous commands.
+
+      The history facilities are also placed into a separate library,
+      the History library, as part of the build process.  The History
+      library may be used without Readline in applications which
+      desire its capabilities.
+    '';
+
+    homepage = "https://savannah.gnu.org/projects/readline/";
+
+    license = licenses.gpl3Plus;
+
+    maintainers = with maintainers; [ dtzWill ];
+
+    platforms = platforms.unix;
+    branch = "8.1";
+  };
+}
diff --git a/pkgs/development/libraries/readline/readline-8.1-patches.nix b/pkgs/development/libraries/readline/readline-8.1-patches.nix
new file mode 100644
index 00000000000..b8019fb3350
--- /dev/null
+++ b/pkgs/development/libraries/readline/readline-8.1-patches.nix
@@ -0,0 +1,4 @@
+# Automatically generated by `update-patch-set.sh'; do not edit.
+
+patch: [
+]
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index aa67263ce6f..2c0d974f248 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -17106,6 +17106,8 @@ in
 
   readline80 = callPackage ../development/libraries/readline/8.0.nix { };
 
+  readline81 = callPackage ../development/libraries/readline/8.1.nix { };
+
   readosm = callPackage ../development/libraries/readosm { };
 
   rinutils = callPackage ../development/libraries/rinutils { };