From e714798f27be8a48a0712baf2b150f0e1c7ceeb9 Mon Sep 17 00:00:00 2001
From: Daniel Schaefer <git@danielschaefer.me>
Date: Thu, 19 Sep 2019 19:58:50 +0200
Subject: [PATCH] sqldiff: init at 3.28.0

---
 pkgs/development/libraries/sqlite/tools.nix | 43 +++++++++++++++++++++
 pkgs/top-level/all-packages.nix             |  4 +-
 2 files changed, 46 insertions(+), 1 deletion(-)
 create mode 100644 pkgs/development/libraries/sqlite/tools.nix

diff --git a/pkgs/development/libraries/sqlite/tools.nix b/pkgs/development/libraries/sqlite/tools.nix
new file mode 100644
index 00000000000..6e97f06e617
--- /dev/null
+++ b/pkgs/development/libraries/sqlite/tools.nix
@@ -0,0 +1,43 @@
+{ stdenv, fetchurl, unzip, sqlite, tcl }:
+
+let
+  archiveVersion = import ./archive-version.nix stdenv.lib;
+  mkTool = { pname, makeTarget, description, homepage }: stdenv.mkDerivation rec {
+    inherit pname;
+    version = "3.28.0";
+
+    src = assert version == sqlite.version; fetchurl {
+      url = "https://sqlite.org/2019/sqlite-src-${archiveVersion version}.zip";
+      sha256 = "15v57b113bpgcshfsx5jw93szar3da94rr03i053xhl15la7jllh";
+    };
+
+    nativeBuildInputs = [ unzip ];
+    buildInputs = [ tcl ];
+
+    makeFlags = [ makeTarget ];
+
+    installPhase = "install -Dt $out/bin ${makeTarget}";
+
+    meta = with stdenv.lib; {
+      inherit description homepage;
+      downloadPage = http://sqlite.org/download.html;
+      license = licenses.publicDomain;
+      maintainers = with maintainers; [ pesterhazy johnazoidberg ];
+      platforms = platforms.unix;
+    };
+  };
+in
+{
+  sqldiff = mkTool {
+    pname = "sqldiff";
+    makeTarget = "sqldiff";
+    description = "A tool that displays the differences between SQLite databases";
+    homepage = "https://www.sqlite.org/sqldiff.html";
+  };
+  sqlite-analyzer = mkTool {
+    pname = "sqlite-analyzer";
+    makeTarget = "sqlite3_analyzer";
+    description = "A tool that shows statistics about SQLite databases";
+    homepage = "https://www.sqlite.org/sqlanalyze.html";
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 1fe0c43e78a..f690ca56c0a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -15412,7 +15412,9 @@ in
 
   sqlite = lowPrio (callPackage ../development/libraries/sqlite { });
 
-  sqlite-analyzer = lowPrio (callPackage ../development/libraries/sqlite/analyzer.nix { });
+  sqlite-analyzer = lowPrio (callPackage ../development/libraries/sqlite/tools.nix { }).sqlite-analyzer;
+
+  sqldiff = lowPrio (callPackage ../development/libraries/sqlite/tools.nix { }).sqldiff;
 
   sqlar = callPackage ../development/libraries/sqlite/sqlar.nix { };