From d9b78f206ff0ecfd43ebba35adf9388c5cf44679 Mon Sep 17 00:00:00 2001
From: Evgeny Egorochkin <phreedom.stdin@gmail.com>
Date: Sun, 20 Jun 2010 23:48:59 +0000
Subject: [PATCH] Added Quassel IRC client. By default it's compiled as
 monolithic, but as soon as there's a corresponding service, it should be
 changed to client/daemon split.

svn path=/nixpkgs/trunk/; revision=22351
---
 .../networking/irc/quassel/default.nix        | 56 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  5 ++
 2 files changed, 61 insertions(+)
 create mode 100644 pkgs/applications/networking/irc/quassel/default.nix

diff --git a/pkgs/applications/networking/irc/quassel/default.nix b/pkgs/applications/networking/irc/quassel/default.nix
new file mode 100644
index 00000000000..eadf4525e1f
--- /dev/null
+++ b/pkgs/applications/networking/irc/quassel/default.nix
@@ -0,0 +1,56 @@
+{ monolithic ? true # build monolithic Quassel
+, daemon ? false # build Quassel daemon
+, client ? false # build Quassel client
+, kde ? true # enable KDE integration
+, ssl ? true # enable SSL support
+, previews ? false # enable webpage previews on hovering over URLs
+, stdenv, fetchurl, cmake, qt4, kdelibs ? null, automoc4 ? null, phonon ? null }:
+
+assert kde -> kdelibs != null && automoc4 != null && phonon != null;
+
+let
+  edf = flag: feature: [("-D" + feature + (if flag then "=ON" else "=OFF"))];
+
+in with stdenv; mkDerivation rec {
+
+  name = "quassel-0.6.1";
+
+  src = fetchurl {
+    url = "http://quassel-irc.org/pub/${name}.tar.bz2";
+    sha256 = "1v5mxligfygn7r7hm3b9by38qxigncfkp6w4n8ypp8ww6n8ml6z0";
+  };
+
+  buildInputs = [ cmake qt4 ]
+    ++ lib.optional kde kdelibs
+    ++ lib.optional kde automoc4
+    ++ lib.optional kde phonon;
+
+  cmakeFlags = [
+    "-DWITH_DBUS=OFF"
+    "-DWITH_LIBINDICATE=OFF"
+    "-DEMBED_DATA=OFF"
+    "-DSTATIC=OFF"
+    "-DWITH_PHONON=ON" ]
+    ++ edf monolithic "WANT_MONO"
+    ++ edf daemon "WANT_CORE"
+    ++ edf client "WANT_QTCLIENT"
+    ++ edf kde "WITH_KDE"
+    ++ edf ssl "WITH_OPENSSL"
+    ++ edf previews "WITH_WEBKIT"  ;
+
+  meta = {
+    homepage = http://quassel-irc.org/;
+    description = "Qt4/KDE4 distributed IRC client suppporting a remote daemon";
+    longDescription = ''
+      Quassel IRC is a cross-platform, distributed IRC client,
+      meaning that one (or multiple) client(s) can attach to
+      and detach from a central core -- much like the popular
+      combination of screen and a text-based IRC client such
+      as WeeChat, but graphical(based on Qt4/KDE4).
+    '';
+    license = "GPLv3";
+    maintainers = [ stdenv.lib.maintainers.phreedom ];
+  };
+
+}
+
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 3faf1e2a6e1..87c7aae3535 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5177,6 +5177,11 @@ let
     qt4 = qt46;
   };
 
+  quassel = makeOverridable (import ../applications/networking/irc/quassel) {
+    inherit stdenv fetchurl cmake;
+    inherit (kde4) qt4 kdelibs phonon automoc4;
+  };
+  
   quesoglc = import ../development/libraries/quesoglc {
     inherit stdenv fetchurl mesa glew freetype fontconfig fribidi;
     inherit (xlibs) libX11;