From 3f02885d061da35db34d18fb6d8c7c3a90ee6162 Mon Sep 17 00:00:00 2001
From: Emery Hemingway <emery@vfemail.net>
Date: Sat, 21 Feb 2015 21:56:50 -0500
Subject: [PATCH 1/2] u9fs: initial package

---
 pkgs/servers/u9fs/default.nix   | 24 ++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix |  2 ++
 2 files changed, 26 insertions(+)
 create mode 100644 pkgs/servers/u9fs/default.nix

diff --git a/pkgs/servers/u9fs/default.nix b/pkgs/servers/u9fs/default.nix
new file mode 100644
index 00000000000..dc855294fbd
--- /dev/null
+++ b/pkgs/servers/u9fs/default.nix
@@ -0,0 +1,24 @@
+{ stdenv, fetchhg }:
+
+stdenv.mkDerivation {
+  name = "u9fs-20110513";
+  src = fetchhg {
+    url = https://code.google.com/p/u9fs;
+    rev = "9474edb23b11";
+    sha256 = "0irwyk8vnvx0fmz8lmbdb2jrlvas8imr61jr76a1pkwi9wpf2wv6";
+  };
+
+  installPhase =
+    ''
+      mkdir -p $out/bin $out/share/man4
+      cp u9fs $out/bin; cp u9fs.man $out/share/man4
+    '';
+
+  meta = with stdenv.lib;
+    { description = "Serve 9P from Unix";
+      homepage = https://code.google.com/p/u9fs;
+      license = licenses.free;
+      maintainers = [ maintainers.emery ];
+      platforms = platforms.unix;
+    };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 3dd8284bbc9..b04e3ca85b4 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -2779,6 +2779,8 @@ let
 
   txt2man = callPackage ../tools/misc/txt2man { };
 
+  u9fs = callPackage ../servers/u9fs { };
+
   ucl = callPackage ../development/libraries/ucl { };
 
   ucspi-tcp = callPackage ../tools/networking/ucspi-tcp { };

From 446580f3cd5a642e811e31172639eadbebeda61b Mon Sep 17 00:00:00 2001
From: Emery Hemingway <emery@vfemail.net>
Date: Sun, 22 Feb 2015 10:07:30 -0500
Subject: [PATCH 2/2] nixos: u9fs service module

---
 nixos/modules/module-list.nix                 |  1 +
 .../services/network-filesystems/u9fs.nix     | 75 +++++++++++++++++++
 2 files changed, 76 insertions(+)
 create mode 100644 nixos/modules/services/network-filesystems/u9fs.nix

diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index c41ae69c1ac..103cded78b0 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -228,6 +228,7 @@
   ./services/network-filesystems/rsyncd.nix
   ./services/network-filesystems/samba.nix
   ./services/network-filesystems/diod.nix
+  ./services/network-filesystems/u9fs.nix
   ./services/network-filesystems/yandex-disk.nix
   ./services/networking/amuled.nix
   ./services/networking/atftpd.nix
diff --git a/nixos/modules/services/network-filesystems/u9fs.nix b/nixos/modules/services/network-filesystems/u9fs.nix
new file mode 100644
index 00000000000..64809727464
--- /dev/null
+++ b/nixos/modules/services/network-filesystems/u9fs.nix
@@ -0,0 +1,75 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.services.u9fs;
+in
+{
+
+  options = {
+
+    services.u9fs = {
+
+      enable = mkOption {
+        type = types.bool;
+        default = false;
+        description = "Whether to run the u9fs 9P server for Unix.";
+      };
+
+      listenStreams = mkOption {
+        type = types.listOf types.str;
+        default = [ "564" ];
+        example = [ "192.168.16.1:564" ];
+        description = ''
+          Sockets to listen for clients on.
+          See <command>man 5 systemd.socket</command> for socket syntax.
+        '';
+      };
+
+      extraArgs = mkOption {
+        type = types.str;
+        default = "";
+        example = "-a none -u nobody";
+        description =
+          ''
+            Extra arguments to pass on invocation,
+            see <command>man 4 u9fs</command>
+          '';
+      };
+
+      fsroot = mkOption {
+        type = types.path;
+        default = "/";
+        example = "/srv";
+        description = "File system root to serve to clients.";
+      };
+
+    };
+
+  };
+
+  config = mkIf cfg.enable {
+
+    systemd = {
+      sockets.u9fs = {
+        description = "U9fs Listening Socket";
+        wantedBy = [ "sockets.target" ];
+        inherit (cfg) listenStreams;
+        socketConfig.Accept = "yes";
+      };
+      services."u9fs@" = {
+        description = "9P Protocol Server";
+        reloadIfChanged = true;
+        requires = [ "u9fs.socket" ];
+        serviceConfig =
+          { ExecStart = "-${pkgs.u9fs}/bin/u9fs ${cfg.extraArgs} ${cfg.fsroot}";
+            StandardInput = "socket";
+            StandardError = "journal";
+          };
+      };
+    };
+
+  };
+
+}