s6: move to tools/system

Matches runit, a similar process supervisor.

pkgs/tools/system/s6/default.nix

@@ -0,0 +1,44 @@
+{ stdenv, execline, fetchgit, skalibs }:
+
+let
+
+  version = "2.2.1.0";
+
+in stdenv.mkDerivation rec {
+
+  name = "s6-${version}";
+
+  src = fetchgit {
+    url = "git://git.skarnet.org/s6";
+    rev = "refs/tags/v${version}";
+    sha256 = "1g8gr3znxj8lyqpwrmgzh47yb64zldrvvvgpp1m4pb37k5k11bj9";
+  };
+
+  dontDisableStatic = true;
+
+  enableParallelBuilding = true;
+
+  configureFlags = [
+    "--with-sysdeps=${skalibs}/lib/skalibs/sysdeps"
+    "--with-include=${skalibs}/include"
+    "--with-include=${execline}/include"
+    "--with-lib=${skalibs}/lib"
+    "--with-lib=${execline}/lib"
+    "--with-dynlib=${skalibs}/lib"
+    "--with-dynlib=${execline}/lib"
+  ] ++ [ (if stdenv.isDarwin then "--disable-shared" else "--enable-shared") ];
+
+  preBuild = ''
+    substituteInPlace "src/daemontools-extras/s6-log.c" \
+      --replace '"execlineb"' '"${execline}/bin/execlineb"'
+  '';
+
+  meta = {
+    homepage = http://www.skarnet.org/software/s6/;
+    description = "skarnet.org's small & secure supervision software suite";
+    platforms = stdenv.lib.platforms.all;
+    license = stdenv.lib.licenses.isc;
+    maintainers = with stdenv.lib.maintainers; [ pmahoney ];
+  };
+
+}