From cff179f829650be1de32f030dfb73c7b8284ed76 Mon Sep 17 00:00:00 2001
From: Austin Seipp <aseipp@pobox.com>
Date: Mon, 31 Mar 2014 10:56:02 -0500
Subject: [PATCH] hashcat: version 0.47

Signed-off-by: Austin Seipp <aseipp@pobox.com>
---
 pkgs/tools/security/hashcat/default.nix | 48 +++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix         |  2 ++
 2 files changed, 50 insertions(+)
 create mode 100644 pkgs/tools/security/hashcat/default.nix

diff --git a/pkgs/tools/security/hashcat/default.nix b/pkgs/tools/security/hashcat/default.nix
new file mode 100644
index 00000000000..5e173724190
--- /dev/null
+++ b/pkgs/tools/security/hashcat/default.nix
@@ -0,0 +1,48 @@
+{ stdenv, fetchurl, p7zip, patchelf }:
+
+let
+  bits    = if stdenv.system == "x86_64-linux" then "64" else "32";
+  libPath = stdenv.lib.makeLibraryPath [ stdenv.gcc.libc ];
+
+  fixBin = x: ''
+    patchelf --interpreter "$(cat $NIX_GCC/nix-support/dynamic-linker)" \
+      --set-rpath ${libPath} ${x}
+  '';
+in
+stdenv.mkDerivation rec {
+  name    = "hashcat-${version}";
+  version = "0.47";
+
+  src = fetchurl {
+    url    = "http://hashcat.net/files/${name}.7z";
+    sha256 = "0mc4lv4qfxabp794xfzgr63fhwk7lvbg12pry8a96lldp0jwp6i3";
+  };
+
+  buildInputs = [ p7zip patchelf ];
+
+  unpackPhase = "7z x $src > /dev/null && cd ${name}";
+
+  installPhase = ''
+    mkdir -p $out/bin $out/libexec
+    cp -R * $out/libexec
+
+    echo -n "/" > $out/bin/eula.accepted
+    ln -s $out/libexec/hashcat-cli${bits}.bin $out/bin/hashcat
+    ln -s $out/libexec/hashcat-cliXOP.bin $out/bin/hashcat-xop
+    ln -s $out/libexec/hashcat-cliAVX.bin $out/bin/hashcat-avx
+  '';
+
+  fixupPhase = ''
+    ${fixBin "$out/libexec/hashcat-cli${bits}.bin"}
+    ${fixBin "$out/libexec/hashcat-cliXOP.bin"}
+    ${fixBin "$out/libexec/hashcat-cliAVX.bin"}
+  '';
+
+  meta = {
+    description = "Fast password cracker";
+    homepage    = "http://hashcat.net/hashcat/";
+    license     = stdenv.lib.licenses.unfreeRedistributable;
+    platforms   = stdenv.lib.platforms.linux;
+    maintainers = [ stdenv.lib.maintainers.thoughtpolice ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index df25e7dec5c..f7e7e51dc78 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1172,6 +1172,8 @@ let
 
   hardlink = callPackage ../tools/system/hardlink { };
 
+  hashcat = callPackage ../tools/security/hashcat { };
+
   halibut = callPackage ../tools/typesetting/halibut { };
 
   hddtemp = callPackage ../tools/misc/hddtemp { };