* Added Firefox 3.6. It's not entirely stable yet though. In

particular it segfaults with the `-P' option.

svn path=/nixpkgs/trunk/; revision=19606

pkgs/applications/networking/browsers/firefox/3.6.nix

@@ -0,0 +1,139 @@
+{ stdenv, fetchurl, pkgconfig, gtk, pango, perl, python, zip, libIDL
+, libjpeg, libpng, zlib, cairo, dbus, dbus_glib, bzip2, xlibs
+, freetype, fontconfig, file, alsaLib, nspr, nss, libnotify
+
+, # If you want the resulting program to call itself "Firefox" instead
+  # of "Shiretoko" or whatever, enable this option.  However, those
+  # binaries may not be distributed without permission from the
+  # Mozilla Foundation, see
+  # http://www.mozilla.org/foundation/trademarks/.
+  enableOfficialBranding ? false
+}:
+
+rec {
+
+  firefoxVersion = "3.6";
+  
+  xulVersion = "1.9.2"; # this attribute is used by other packages
+
+  
+  src = fetchurl {
+    url = "http://releases.mozilla.org/pub/mozilla.org/firefox/releases/${firefoxVersion}/source/firefox-${firefoxVersion}.source.tar.bz2";
+    sha1 = "33226b45a0bcd795545a980cab475c5492f0ea69";
+  };
+
+
+  commonConfigureFlags =
+    [ "--enable-optimize"
+      "--disable-debug"
+      "--enable-strip"
+      "--with-system-jpeg"
+      "--with-system-zlib"
+      "--with-system-bz2"
+      "--with-system-nspr"
+      #"--with-system-nss"
+      # "--with-system-png" # <-- "--with-system-png won't work because the system's libpng doesn't have APNG support"
+      "--enable-system-cairo"
+      #"--enable-system-sqlite" # <-- this seems to be discouraged
+      "--disable-crashreporter"
+      "--disable-tests"
+      "--disable-necko-wifi" # maybe we want to enable this at some point
+    ];
+
+
+  xulrunner = stdenv.mkDerivation {
+    name = "xulrunner-${xulVersion}";
+    
+    inherit src;
+
+    buildInputs =
+      [ pkgconfig gtk perl zip libIDL libjpeg libpng zlib cairo bzip2
+        python dbus dbus_glib pango freetype fontconfig xlibs.libXi
+        xlibs.libX11 xlibs.libXrender xlibs.libXft xlibs.libXt file
+        alsaLib nspr /* nss */ libnotify
+      ];
+
+    configureFlags =
+      [ "--enable-application=xulrunner"
+        "--disable-javaxpcom"
+      ] ++ commonConfigureFlags;
+
+    # !!! Temporary hack.
+    preBuild = ''
+     export NIX_ENFORCE_PURITY=
+    '';
+
+    installFlags = "SKIP_GRE_REGISTRATION=1";
+
+    postInstall = ''
+      # Fix some references to /bin paths in the Xulrunner shell script.
+      substituteInPlace $out/bin/xulrunner \
+          --replace /bin/pwd "$(type -tP pwd)" \
+          --replace /bin/ls "$(type -tP ls)"
+
+      # Fix run-mozilla.sh search
+      libDir=$(cd $out/lib && ls -d xulrunner-[0-9]*)
+      echo libDir: $libDir
+      test -n "$libDir"
+      cd $out/bin
+      mv xulrunner ../lib/$libDir/
+
+      for i in $out/lib/$libDir/*; do 
+          file $i;
+          if file $i | grep executable &>/dev/null; then 
+              ln -s $i $out/bin
+          fi;
+      done;
+      rm -f $out/bin/run-mozilla.sh
+    ''; # */
+
+    meta = {
+      description = "Mozilla Firefox XUL runner";
+      homepage = http://www.mozilla.com/en-US/firefox/;
+    };
+
+    passthru = { inherit gtk; version = xulVersion; };
+  };
+
+
+  firefox = stdenv.mkDerivation rec {
+    name = "firefox-${firefoxVersion}";
+
+    inherit src;
+
+    buildInputs =
+      [ pkgconfig gtk perl zip libIDL libjpeg zlib cairo bzip2 python
+        dbus dbus_glib pango freetype fontconfig alsaLib nspr libnotify
+      ];
+
+    propagatedBuildInputs = [xulrunner];
+
+    configureFlags =
+      [ "--enable-application=browser"
+        "--with-libxul-sdk=${xulrunner}/lib/xulrunner-devel-${xulrunner.version}"
+      ]
+      ++ commonConfigureFlags
+      ++ stdenv.lib.optional enableOfficialBranding "--enable-official-branding";
+
+    postInstall = ''
+      libDir=$(cd $out/lib && ls -d firefox-[0-9]*)
+      test -n "$libDir"
+
+      ln -s ${xulrunner}/lib/xulrunner-${xulrunner.version} $out/lib/$libDir/xulrunner
+
+      # Register extensions etc. !!! is this needed anymore?
+      echo "running firefox -register..."
+      $out/bin/firefox -register
+    ''; # */
+
+    meta = {
+      description = "Mozilla Firefox - the browser, reloaded";
+      homepage = http://www.mozilla.com/en-US/firefox/;
+    };
+
+    passthru = {
+      inherit gtk xulrunner nspr;
+      isFirefox3Like = true;
+    };
+  };
+}

pkgs/development/libraries/libnotify/default.nix

@@ -1,17 +1,17 @@
-args: with args;
+{ stdenv, fetchurl, pkgconfig, dbus, dbus_glib, gtk, glib }:
  
-stdenv.mkDerivation {
+stdenv.mkDerivation rec {
-  name = "libnotify-0.4.4";
+  name = "libnotify-0.4.5";
-  #builder = ./builder.sh;
 
   src = fetchurl {
-    url = http://www.galago-project.org/files/releases/source/libnotify/libnotify-0.4.4.tar.gz;
+    url = "http://www.galago-project.org/files/releases/source/libnotify/${name}.tar.gz";
-    sha256 = "2389a9b8220f776033f728a8d46352cfee5c8705066e34887bfb188f9f0d3856";
+    sha256 = "1ndh7wpm9qh12vm5avjrq2xv1j681j9qq6j2fyj6a2shl67dp687";
   };
 
-  buildInputs = [
+  buildInputs = [ pkgconfig dbus.libs dbus_glib gtk glib ];
-    pkgconfig dbus.libs dbus_glib gtk glib
-  ];
 
-  configureFlags="";
+  meta = {
+    homepage = http://galago-project.org/;
+    description = "A library that sends desktop notifications to a notification daemon";
+  };
 }

pkgs/top-level/all-packages.nix

@@ -6876,18 +6876,28 @@ let
 
   firefoxWrapper = firefox35Wrapper;
 
-  firefox35Pkgs = lowPrio (import ../applications/networking/browsers/firefox/3.5.nix {
+  firefox35Pkgs = import ../applications/networking/browsers/firefox/3.5.nix {
     inherit fetchurl stdenv pkgconfig perl zip libjpeg libpng zlib cairo
       python dbus dbus_glib freetype fontconfig bzip2 xlibs file alsaLib
       nspr nss;
     inherit (gtkLibs) gtk pango;
     inherit (gnome) libIDL;
-  });
+  };
 
   firefox35 = firefox35Pkgs.firefox;
   xulrunner35 = firefox35Pkgs.xulrunner;
   firefox35Wrapper = wrapFirefox firefox35 "firefox" "";
 
+  firefox36Pkgs = import ../applications/networking/browsers/firefox/3.6.nix {
+    inherit fetchurl stdenv pkgconfig perl zip libjpeg libpng zlib cairo
+      python dbus dbus_glib freetype fontconfig bzip2 xlibs file alsaLib
+      nspr nss libnotify;
+    inherit (gtkLibs) gtk pango;
+    inherit (gnome) libIDL;
+  };
+
+  firefox36Wrapper = lowPrio (wrapFirefox firefox36Pkgs.firefox "firefox" "");
+  
   flac = import ../applications/audio/flac {
     inherit fetchurl stdenv libogg;
   };
@@ -6897,7 +6907,7 @@ let
   flashplayer9 = (
     import ../applications/networking/browsers/mozilla-plugins/flashplayer-9 {
       inherit fetchurl stdenv zlib alsaLib nss nspr fontconfig freetype expat;
-      inherit (xlibs) libX11 libXext libXrender libXt ;
+      inherit (xlibs) libX11 libXext libXrender libXt;
       inherit (gtkLibs) gtk glib pango atk;
     });
 

pkgs/top-level/release.nix

@@ -156,7 +156,6 @@ in {
   feh = linux;
   file = all;
   findutils = all;
-  firefox35 = prio 150 linux;
   flex = all;
   flex2535 = all;
   fontforge = linux;
@@ -455,6 +454,14 @@ in {
     jdee = linux;
   };
 
+  firefox35Pkgs = {
+    firefox = prio 150 linux;
+  };
+  
+  firefox36Pkgs = {
+    firefox = linux;
+  };
+  
   gnome = {
     gnome_panel = linux;
     metacity = linux;