mirage-crypto{,-rng,-pk}: init at 0.6.2

pkgs/development/ocaml-modules/mirage-crypto/default.nix

@@ -0,0 +1,33 @@
+{ lib, fetchurl, buildDunePackage, ounit, cstruct, ocplib-endian
+, cpuid, dune-configurator, cpuAcceleration ? false }:
+
+buildDunePackage rec {
+  minimumOCamlVersion = "4.07";
+
+  pname = "mirage-crypto";
+  version = "0.6.2";
+
+  src = fetchurl {
+    url = "https://github.com/mirage/mirage-crypto/releases/download/v${version}/mirage-crypto-v${version}.tbz";
+    sha256 = "08xq49cxn66yi0gfajzi8czcxfx24rd191rvf7s10wfkz304sa72";
+  };
+
+  useDune2 = true;
+
+  preBuild = ''
+    MIRAGE_CRYPTO_ACCELERATE=${lib.boolToString cpuAcceleration}
+  '';
+
+  doCheck = true;
+  checkInputs = [ ounit ];
+
+  nativeBuildInputs = [ cpuid dune-configurator ];
+  propagatedBuildInputs = [ cstruct ocplib-endian ];
+
+  meta = with lib; {
+    homepage = "https://github.com/mirage/mirage-crypto";
+    description = "Simple symmetric cryptography for the modern age";
+    license = licenses.isc;
+    maintainers = with maintainers; [ sternenseemann ];
+  };
+}

pkgs/development/ocaml-modules/mirage-crypto/pk.nix

@@ -0,0 +1,19 @@
+{ buildDunePackage, ounit, randomconv, mirage-crypto, mirage-crypto-rng
+, cstruct, sexplib, ppx_sexp_conv, zarith, eqaf, rresult, gmp }:
+
+buildDunePackage {
+  pname = "mirage-crypto-pk";
+
+  inherit (mirage-crypto) version src useDune2 minimumOCamlVersion;
+
+  buildInputs = [ gmp ];
+  propagatedBuildInputs = [ cstruct mirage-crypto mirage-crypto-rng
+                            zarith eqaf rresult sexplib ppx_sexp_conv ];
+
+  doCheck = true;
+  checkInputs = [ ounit randomconv ];
+
+  meta = mirage-crypto.meta // {
+    description = "Simple public-key cryptography for the modern age";
+  };
+}

pkgs/development/ocaml-modules/mirage-crypto/rng.nix

@@ -0,0 +1,16 @@
+{ buildDunePackage, mirage-crypto, ounit, randomconv, cstruct }:
+
+buildDunePackage {
+  pname = "mirage-crypto-rng";
+
+  inherit (mirage-crypto) version src nativeBuildInputs useDune2 minimumOCamlVersion;
+
+  doCheck = true;
+  checkInputs = [ ounit randomconv ];
+
+  propagatedBuildInputs = [ cstruct mirage-crypto ];
+
+  meta = mirage-crypto.meta // {
+    description = "A cryptographically secure PRNG";
+  };
+}

pkgs/top-level/ocaml-packages.nix

@@ -538,6 +538,12 @@ let
 
     mirage-clock = callPackage ../development/ocaml-modules/mirage-clock { };
 
+    mirage-crypto = callPackage ../development/ocaml-modules/mirage-crypto { };
+
+    mirage-crypto-pk = callPackage ../development/ocaml-modules/mirage-crypto/pk.nix { };
+
+    mirage-crypto-rng = callPackage ../development/ocaml-modules/mirage-crypto/rng.nix { };
+
     mirage-device = callPackage ../development/ocaml-modules/mirage-device { };
 
     mirage-flow = callPackage ../development/ocaml-modules/mirage-flow { };