From bcde5c33533ea79c40be71273e596a7531d695ed Mon Sep 17 00:00:00 2001
From: Tobias Geerinckx-Rice <me@tobias.gr>
Date: Mon, 20 Jun 2016 16:04:35 +0200
Subject: [PATCH] ganttproject-bin: init at 2.7.2-r1954

---
 .../misc/ganttproject-bin/default.nix         | 56 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 58 insertions(+)
 create mode 100644 pkgs/applications/misc/ganttproject-bin/default.nix

diff --git a/pkgs/applications/misc/ganttproject-bin/default.nix b/pkgs/applications/misc/ganttproject-bin/default.nix
new file mode 100644
index 00000000000..1b29def11ad
--- /dev/null
+++ b/pkgs/applications/misc/ganttproject-bin/default.nix
@@ -0,0 +1,56 @@
+{ stdenv, fetchzip, makeDesktopItem, makeWrapper
+, jre }:
+
+stdenv.mkDerivation rec {
+  name = "ganttproject-bin-${version}";
+  version = "2.7.2";
+
+  src = let build = "r1954"; in fetchzip {
+    sha256 = "0l655w6n88j7klz56af8xkpiv1pwlkfl5x1d33sqv9dnyisyw2hc";
+    url = "https://dl.ganttproject.biz/ganttproject-${version}/"
+        + "ganttproject-${version}-${build}.zip";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ jre ];
+
+  phases = [ "unpackPhase" "installPhase" "fixupPhase" ];
+
+  installPhase = let
+
+    desktopItem = makeDesktopItem {
+      name = "ganttproject";
+      exec = "ganttproject";
+      icon = "ganttproject";
+      desktopName = "GanttProject";
+      genericName = "Shedule and manage projects";
+      comment = meta.description;
+      categories = "Office;Application;";
+    };
+
+  in ''
+    mkdir -pv "$out/share/ganttproject"
+    cp -rv *  "$out/share/ganttproject"
+
+    mkdir -pv "$out/bin"
+    wrapProgram "$out/share/ganttproject/ganttproject" \
+      --set JAVA_HOME "${jre}"
+    mv -v "$out/share/ganttproject/ganttproject" "$out/bin"
+
+    install -v -Dm644 \
+      plugins/net.sourceforge.ganttproject/data/resources/icons/ganttproject.png \
+      "$out/share/pixmaps/ganttproject.png"
+    cp -rv "${desktopItem}/share/applications" "$out/share"
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Project scheduling and management";
+    homepage = https://www.ganttproject.biz/;
+    downloadPage = https://www.ganttproject.biz/download;
+    # GanttProject itself is GPL3+. All bundled libraries are declared
+    # ‘GPL3-compatible’. See ${downloadPage} for detailed information.
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ nckx ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index ccfd30d72d9..95c5ada10ef 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -12625,6 +12625,8 @@ in
 
   fvwm = callPackage ../applications/window-managers/fvwm { };
 
+  ganttproject-bin = callPackage ../applications/misc/ganttproject-bin { };
+
   geany = callPackage ../applications/editors/geany { };
   geany-with-vte = callPackage ../applications/editors/geany/with-vte.nix { };