From b8ce6a31f555a2e4471880cc4c01b629e7d6d36f Mon Sep 17 00:00:00 2001
From: John Ericson <John.Ericson@Obsidian.Systems>
Date: Tue, 11 Sep 2018 18:17:20 -0400
Subject: [PATCH] elf-header: Init at <libc version>

A little shim derivation to get this header for Darwin, where it is
needed for cross compilation.

There's no real reason to do glibc and musl like that, but as I'm
maintaining it I suppose I can go overboard like that.
---
 .../libraries/elf-header/default.nix          | 43 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  8 ++++
 2 files changed, 51 insertions(+)
 create mode 100644 pkgs/development/libraries/elf-header/default.nix

diff --git a/pkgs/development/libraries/elf-header/default.nix b/pkgs/development/libraries/elf-header/default.nix
new file mode 100644
index 00000000000..48e5b73d9e7
--- /dev/null
+++ b/pkgs/development/libraries/elf-header/default.nix
@@ -0,0 +1,43 @@
+{ stdenvNoCC, lib, glibc, musl }:
+
+let
+   libc =
+     if stdenvNoCC.targetPlatform.isMusl
+     then musl
+     else glibc;
+   headerPath =
+     if stdenvNoCC.targetPlatform.isMusl
+     then "musl-${libc.version}/include/elf.h"
+     else "glibc-${libc.version}/elf/elf.h";
+in
+
+stdenvNoCC.mkDerivation {
+  name = "elf-header";
+  inherit (libc) version;
+
+  src = null;
+
+  unpackPhase = "true";
+
+  dontBuild = true;
+
+  installPhase = ''
+    mkdir -p "$out/include";
+    tar -xf \
+        ${lib.escapeShellArg libc.src} \
+        ${lib.escapeShellArg headerPath} \
+        --to-stdout \
+      | sed -e '/features\.h/d' \
+      > "$out/include/elf.h"
+  '';
+
+  meta = libc.meta // {
+    description = "The datastructures of ELF according to the target platform's libc";
+    longDescription = ''
+	  The Executable and Linkable Format (ELF, formerly named Extensible Linking
+	  Format), is usually defined in a header like this.
+	'';
+    platforms = lib.platforms.all;
+    maintainers = [ lib.maintainers.ericson2314 ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index e09e89b0b90..f9df4ea4fb8 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -9513,6 +9513,14 @@ with pkgs;
     installLocales = config.glibc.locales or false;
   };
 
+  # Provided by libc on Operating Systems that use the Extensible Linker Format.
+  elf-header =
+    if stdenv.hostPlatform.parsed.kernel.execFormat.name == "elf"
+    then null
+    else elf-header-real;
+
+  elf-header-real = callPackage ../development/libraries/elf-header { };
+
   glibc_memusage = callPackage ../development/libraries/glibc {
     installLocales = false;
     withGd = true;