gwenhywfar, libchipcard: Move into aqbanking dir

This should make it easier to deduplicate things, such as fetching
upstream sources and the plugin paths, because after all these libraries
are aqbanking-related and maintained by the same author on the same
site.

Signed-off-by: aszlig <aszlig@redmoonstudios.org>
Cc: @cillianderoiste, @urkud

pkgs/development/libraries/aqbanking/gwenhywfar.nix

@@ -0,0 +1,57 @@
+{ stdenv, fetchurl, gnutls, gtk, libgcrypt, pkgconfig, gettext, qt4 }:
+
+stdenv.mkDerivation rec {
+  name = "gwenhywfar-${version}";
+  version = "4.15.3";
+
+  src = let
+    releaseNum = 201; # Change this on update
+    qstring = "package=01&release=${toString releaseNum}&file=01";
+    mkURLs = map (base: "${base}/sites/download/download.php?${qstring}");
+  in fetchurl {
+    name = "${name}.tar.gz";
+    urls = mkURLs [ "http://www.aquamaniac.de" "http://www2.aquamaniac.de" ];
+    sha256 = "0fp67s932x66xfljb26zbrn8ambbc5y5c3hllr6l284nr63qf3ka";
+  };
+
+  postPatch = let
+    pluginSearchPaths = [
+      "/run/current-system/sw/lib/gwenhywfar/plugins"
+      ".nix-profile/lib/gwenhywfar/plugins"
+    ];
+    isRelative = path: builtins.substring 0 1 path != "/";
+    mkSearchPath = path: ''
+      p; g; s,\<PLUGINDIR\>,"${path}",g;
+    '' + stdenv.lib.optionalString (isRelative path) ''
+      s/AddPath(\(.*\));/AddRelPath(\1, GWEN_PathManager_RelModeHome);/g
+    '';
+
+  in ''
+    sed -i -e '/GWEN_PathManager_DefinePath.*GWEN_PM_PLUGINDIR/,/^#endif/ {
+      /^#if/,/^#endif/ {
+        H; /^#endif/ {
+          ${stdenv.lib.concatMapStrings mkSearchPath pluginSearchPaths}
+        }
+      }
+    }' src/gwenhywfar.c
+
+    # Strip off the effective SO version from the path so that for example
+    # "lib/gwenhywfar/plugins/60" becomes just "lib/gwenhywfar/plugins".
+    sed -i -e '/^gwenhywfar_plugindir=/s,/\''${GWENHYWFAR_SO_EFFECTIVE},,' \
+      configure
+  '';
+
+  nativeBuildInputs = [ pkgconfig gettext ];
+
+  buildInputs = [ gtk qt4 gnutls libgcrypt ];
+
+  QTDIR = qt4;
+
+  meta = with stdenv.lib; {
+    description = "OS abstraction functions used by aqbanking and related tools";
+    homepage = "http://www2.aquamaniac.de/sites/download/packages.php?package=01&showall=1";
+    license = licenses.lgpl21;
+    maintainers = with maintainers; [ goibhniu ];
+    platforms = platforms.linux;
+  };
+}

pkgs/development/libraries/aqbanking/libchipcard.nix

@@ -0,0 +1,32 @@
+{ stdenv, fetchurl, pkgconfig, gwenhywfar, pcsclite, zlib }:
+
+stdenv.mkDerivation rec {
+  name = "libchipcard-${version}";
+  version = "5.0.4";
+
+  src = let
+    releaseNum = 200; # Change this on update
+    qstring = "package=02&release=${toString releaseNum}&file=01";
+    mkURLs = map (base: "${base}/sites/download/download.php?${qstring}");
+  in fetchurl {
+    name = "${name}.tar.gz";
+    urls = mkURLs [ "http://www.aquamaniac.de" "http://www2.aquamaniac.de" ];
+    sha256 = "0fj2h39ll4kiv28ch8qgzdbdbnzs8gl812qnm660bw89rynpjnnj";
+  };
+
+  nativeBuildInputs = [ pkgconfig ];
+
+  buildInputs = [ gwenhywfar pcsclite zlib ];
+
+  makeFlags = [ "crypttokenplugindir=$(out)/lib/gwenhywfar/plugins/ct" ];
+
+  configureFlags = [ "--with-gwen-dir=${gwenhywfar}" ];
+
+  meta = with stdenv.lib; {
+    description = "Library for access to chipcards";
+    homepage = "http://www2.aquamaniac.de/sites/download/packages.php?package=02&showall=1";
+    license = licenses.lgpl21;
+    maintainers = with maintainers; [ aszlig ];
+    platforms = platforms.linux;
+  };
+}