From abf836b06652a3545fb8b009aeb0bb6600fe3479 Mon Sep 17 00:00:00 2001
From: Robert Helgesson <robert@rycee.net>
Date: Tue, 29 Dec 2015 23:52:11 +0100
Subject: [PATCH] ois: use stdenv

This replaces use of `builderDefsPackage`.
---
 pkgs/development/libraries/ois/default.nix | 81 +++++++++-------------
 1 file changed, 31 insertions(+), 50 deletions(-)

diff --git a/pkgs/development/libraries/ois/default.nix b/pkgs/development/libraries/ois/default.nix
index 67df3645eb9..25bb7a365f2 100644
--- a/pkgs/development/libraries/ois/default.nix
+++ b/pkgs/development/libraries/ois/default.nix
@@ -1,60 +1,41 @@
-x@{builderDefsPackage, fetchurl
-  , autoconf, automake, libtool, m4
-  , libX11, xproto, libXi, inputproto
-  , libXaw, libXmu, libXt
-  , ...}:
-builderDefsPackage
-(a :  
-let 
-  helperArgNames = ["stdenv" "fetchurl" "builderDefsPackage"] ++ 
-    [];
+{ stdenv, fetchurl, autoconf, automake, libtool, libX11, xproto
+, libXi, inputproto, libXaw, libXmu, libXt }:
 
-  buildInputs = map (n: builtins.getAttr n x)
-    (builtins.attrNames (builtins.removeAttrs x helperArgNames));
-  sourceInfo = rec {
-    baseName="ois";
-    majorVersion="1";
-    minorVersion="3";
-    version="${majorVersion}.${minorVersion}";
-    name="${baseName}-${version}";
-    url="mirror://sourceforge/project/wgois/Source%20Release/${version}/ois_v${majorVersion}-${minorVersion}.tar.gz";
-    hash="18gs6xxhbqb91x2gm95hh1pmakimqim1k9c65h7ah6g14zc7dyjh";
-  };
+let
+  majorVersion = "1";
+  minorVersion = "3";
 in
-rec {
-  src = a.fetchurl {
-    url = sourceInfo.url;
-    sha256 = sourceInfo.hash;
+
+stdenv.mkDerivation rec {
+  name = "ois-${version}";
+  version = "${majorVersion}.${minorVersion}";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/project/wgois/Source%20Release/${version}/ois_v${majorVersion}-${minorVersion}.tar.gz";
+    sha256 = "18gs6xxhbqb91x2gm95hh1pmakimqim1k9c65h7ah6g14zc7dyjh";
   };
 
-  inherit (sourceInfo) name version;
-  inherit buildInputs;
+  patches = [
+    (fetchurl {
+      url = http://sources.gentoo.org/cgi-bin/viewvc.cgi/gentoo-x86/dev-games/ois/files/ois-1.3-gcc47.patch;
+      sha256 = "026jw06n42bcrmg0sbdhzc4cqxsnf7fw30a2z9cigd9x282zhii8";
+      name = "gcc47.patch";
+    })
+  ];
 
-  phaseNames = ["doPatch" "doConfigure" "doMakeInstall"];
-
-  patches = [(fetchurl {
-    url = http://sources.gentoo.org/cgi-bin/viewvc.cgi/gentoo-x86/dev-games/ois/files/ois-1.3-gcc47.patch;
-    sha256 = "026jw06n42bcrmg0sbdhzc4cqxsnf7fw30a2z9cigd9x282zhii8";
-    name = "gcc47.patch";
-  })];
   patchFlags = "-p0";
 
-  configureCommand = ''sh bootstrap; sh configure'';
+  buildInputs = [
+    autoconf automake libtool libX11 xproto libXi inputproto libXaw
+    libXmu libXt
+  ];
 
-  meta = {
+  preConfigure = "sh bootstrap";
+
+  meta = with stdenv.lib; {
     description = "Object-oriented C++ input system";
-    maintainers = with a.lib.maintainers;
-    [
-      raskin
-    ];
-    platforms = with a.lib.platforms;
-      linux;
-    license = a.lib.licenses.zlib;
+    maintainers = [ maintainers.raskin ];
+    platforms = platforms.linux;
+    license = licenses.zlib;
   };
-  passthru = {
-    updateInfo = {
-      downloadPage = "http://sourceforge.net/projects/wgois/files/Source Release/";
-    };
-  };
-}) x
-
+}