From a3c72e4d7de5c168c5c29af19488e79b02fdaca4 Mon Sep 17 00:00:00 2001
From: Tom Hall <tahall256@protonmail.ch>
Date: Mon, 28 Dec 2020 20:04:09 +0000
Subject: [PATCH] pure-maps: init at 2.6.0

---
 pkgs/applications/misc/pure-maps/default.nix | 46 ++++++++++++++++++++
 pkgs/top-level/all-packages.nix              |  2 +
 2 files changed, 48 insertions(+)
 create mode 100644 pkgs/applications/misc/pure-maps/default.nix

diff --git a/pkgs/applications/misc/pure-maps/default.nix b/pkgs/applications/misc/pure-maps/default.nix
new file mode 100644
index 00000000000..3ee87d58c08
--- /dev/null
+++ b/pkgs/applications/misc/pure-maps/default.nix
@@ -0,0 +1,46 @@
+{ lib, mkDerivation, fetchFromGitHub, wrapQtAppsHook
+, qmake, qttools, kirigami2, qtquickcontrols2, qtlocation, qtsensors
+, nemo-qml-plugin-dbus, mapbox-gl-qml, s2geometry
+, python3, pyotherside, python3Packages
+}:
+
+mkDerivation rec {
+  pname = "pure-maps";
+  version = "2.6.0";
+
+  src = fetchFromGitHub {
+    owner = "rinigus";
+    repo = "pure-maps";
+    rev = version;
+    sha256 = "1nviq2pavyxwh9k4kyzqpbzmx1wybwdax4pyd017izh9h6gqnjhs";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [ qmake python3 qttools wrapQtAppsHook ];
+  buildInputs = [
+    kirigami2 qtquickcontrols2 qtlocation qtsensors
+    nemo-qml-plugin-dbus pyotherside mapbox-gl-qml s2geometry
+  ];
+  propagatedBuildInputs = with python3Packages; [ gpxpy pyxdg ];
+
+  postPatch = ''
+    substituteInPlace pure-maps.pro \
+      --replace '$$[QT_HOST_BINS]/lconvert' 'lconvert'
+  '';
+
+  qmakeFlags = [ "FLAVOR=kirigami" ];
+
+  dontWrapQtApps = true;
+  postInstall = ''
+    wrapQtApp $out/bin/pure-maps \
+      --prefix PYTHONPATH : "$out/share"
+  '';
+
+  meta = with lib; {
+    description = "Display vector and raster maps, places, routes, and provide navigation instructions with a flexible selection of data and service providers";
+    homepage = "https://github.com/rinigus/pure-maps";
+    license = licenses.gpl3Only;
+    maintainers = [ maintainers.Thra11 ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index b97c08e3a87..eed66e815c9 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -24603,6 +24603,8 @@ in
 
   puremapping = callPackage ../applications/audio/pd-plugins/puremapping { };
 
+  pure-maps = libsForQt5.callPackage ../applications/misc/pure-maps { };
+
   pwdsafety = callPackage ../tools/security/pwdsafety { };
 
   pybitmessage = callPackage ../applications/networking/instant-messengers/pybitmessage { };