From 94a7a80f0b2981d26f6b75db0ca1a7a308552020 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Vladim=C3=ADr=20=C4=8Cun=C3=A1t?= <vcunat@gmail.com>
Date: Sat, 4 Feb 2017 11:53:23 +0100
Subject: [PATCH] Revert "spidermonkey_24: remove"

This reverts commit 5dacc53af3f4537fab693952b5f13b6cafcde6d4.
---
 .../interpreters/spidermonkey/24.nix          | 62 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  1 +
 2 files changed, 63 insertions(+)
 create mode 100644 pkgs/development/interpreters/spidermonkey/24.nix

diff --git a/pkgs/development/interpreters/spidermonkey/24.nix b/pkgs/development/interpreters/spidermonkey/24.nix
new file mode 100644
index 00000000000..6e354c54296
--- /dev/null
+++ b/pkgs/development/interpreters/spidermonkey/24.nix
@@ -0,0 +1,62 @@
+{ stdenv, fetchurl, pkgconfig, nspr, perl, python2, zip, libffi, readline, icu }:
+
+stdenv.mkDerivation rec {
+  version = "24.2.0";
+  name = "spidermonkey-${version}";
+
+  src = fetchurl {
+    url = "mirror://mozilla/js/mozjs-${version}.tar.bz2";
+    sha256 = "1n1phk8r3l8icqrrap4czplnylawa0ddc2cc4cgdz46x3lrkybz6";
+  };
+
+  outputs = [ "out" "dev" "lib" ];
+
+  propagatedBuildInputs = [ nspr ];
+
+  buildInputs = [ pkgconfig perl python2 zip libffi readline icu ];
+
+  postPatch = ''
+    # Fixes an issue with version detection under perl 5.22.x
+    sed -i 's/(defined\((@TEMPLATE_FILE)\))/\1/' config/milestone.pl
+  '';
+
+  postUnpack = "sourceRoot=\${sourceRoot}/js/src";
+
+  preConfigure = ''
+    export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -I${nspr.dev}/include/nspr"
+    export LIBXUL_DIST=$out
+  '';
+
+  setOutputFlags = false;
+  configureFlags = [
+    "--libdir=$(lib)/lib"
+    "--includedir=$(dev)/include"
+    "--enable-threadsafe"
+    "--with-system-icu"
+    "--with-system-nspr"
+    "--with-system-ffi"
+    "--enable-readline"
+  ];
+
+  # hack around a make problem, see https://github.com/NixOS/nixpkgs/issues/1279#issuecomment-29547393
+  preBuild = "touch -- {.,shell,jsapi-tests}/{-lpthread,-ldl}";
+
+  enableParallelBuilding = true;
+
+  doCheck = true;
+  preCheck = "rm jit-test/tests/sunspider/check-date-format-tofte.js"; # https://bugzil.la/600522
+
+  postInstall = ''
+    rm "$lib"/lib/*.a # halve the output size
+    moveToOutput "bin/js*-config" "$dev" # break the cycle
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Mozilla's JavaScript engine written in C/C++";
+    homepage = https://developer.mozilla.org/en/SpiderMonkey;
+    # TODO: MPL/GPL/LGPL tri-license.
+    maintainers = [ maintainers.goibhniu ];
+    platforms = platforms.linux;
+  };
+}
+
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index f74aa2c4176..07a4ce82a5f 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5927,6 +5927,7 @@ with pkgs;
 
   spidermonkey_1_8_5 = callPackage ../development/interpreters/spidermonkey/1.8.5.nix { };
   spidermonkey_17 = callPackage ../development/interpreters/spidermonkey/17.nix { };
+  spidermonkey_24 = callPackage ../development/interpreters/spidermonkey/24.nix { };
   spidermonkey_31 = callPackage ../development/interpreters/spidermonkey/31.nix { };
   spidermonkey_38 = callPackage ../development/interpreters/spidermonkey/38.nix { };
   spidermonkey = spidermonkey_31;