From 70399cc1ce0e182a96e823ebfb0521f5f45d5901 Mon Sep 17 00:00:00 2001
From: Felix Tenley <dev@felschr.com>
Date: Tue, 8 Sep 2020 23:38:24 +0200
Subject: [PATCH 1/2] maintainers: add felschr

---
 maintainers/maintainer-list.nix | 10 ++++++++++
 1 file changed, 10 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index d4131829314..c6c14b438eb 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -2805,6 +2805,16 @@
     githubId = 541748;
     name = "Felipe Espinoza";
   };
+  felschr = {
+    email = "dev@felschr.com";
+    github = "felschr";
+    githubId = 3314323;
+    name = "Felix Tenley";
+    keys = [{
+      longkeyid = "ed25519/0x910ACB9F6BD26F58";
+      fingerprint = "6AB3 7A28 5420 9A41 82D9  0068 910A CB9F 6BD2 6F58";
+    }];
+  };
   ffinkdevs = {
     email = "fink@h0st.space";
     github = "ffinkdevs";

From b1423ee641f16d2470fd4744dc48cf71ed5ae3f3 Mon Sep 17 00:00:00 2001
From: Felix Tenley <dev@felschr.com>
Date: Tue, 8 Sep 2020 23:51:57 +0200
Subject: [PATCH 2/2] filebot: init at 4.9.1

---
 pkgs/applications/video/filebot/default.nix | 54 +++++++++++++++++++++
 pkgs/top-level/all-packages.nix             |  2 +
 2 files changed, 56 insertions(+)
 create mode 100644 pkgs/applications/video/filebot/default.nix

diff --git a/pkgs/applications/video/filebot/default.nix b/pkgs/applications/video/filebot/default.nix
new file mode 100644
index 00000000000..cdd70b4c894
--- /dev/null
+++ b/pkgs/applications/video/filebot/default.nix
@@ -0,0 +1,54 @@
+{ stdenv, fetchurl, openjdk11, makeWrapper, autoPatchelfHook
+, zlib, libzen, libmediainfo, curl, libmms, glib
+}:
+
+let
+  # FileBot requires libcurl-gnutls.so to build
+  curlWithGnuTls = curl.override { gnutlsSupport = true; sslSupport = false; };
+
+in
+
+stdenv.mkDerivation rec {
+  pname = "filebot";
+  version = "4.9.1";
+
+  src = fetchurl {
+    url = "https://get.filebot.net/filebot/FileBot_${version}/FileBot_${version}-portable.tar.xz";
+    sha256 = "0l496cz703mjymjhgmyrkqbfld1bz53pdsbkx00h9a267j22fkms";
+  };
+
+  unpackPhase = "tar xvf $src";
+
+  nativeBuildInputs = [ makeWrapper autoPatchelfHook ];
+
+  buildInputs = [ zlib libzen libmediainfo curlWithGnuTls libmms glib ];
+
+  dontBuild = true;
+  installPhase = ''
+    mkdir -p $out/opt $out/bin
+    # Since FileBot has dependencies on relative paths between files, all required files are copied to the same location as is.
+    cp -r filebot.sh lib/ jar/ $out/opt/
+    # Filebot writes to $APP_DATA, which fails due to read-only filesystem. Using current user .local directory instead.
+    substituteInPlace $out/opt/filebot.sh \
+      --replace 'APP_DATA="$FILEBOT_HOME/data/$USER"' 'APP_DATA=''${XDG_DATA_HOME:-$HOME/.local/share}/filebot/data' \
+      --replace '$FILEBOT_HOME/data/.license' '$APP_DATA/.license'
+    wrapProgram $out/opt/filebot.sh \
+      --prefix PATH : ${stdenv.lib.makeBinPath [ openjdk11 ]}
+    # Expose the binary in bin to make runnable.
+    ln -s $out/opt/filebot.sh $out/bin/filebot
+  '';
+
+  meta = with stdenv.lib; {
+    description = "The ultimate TV and Movie Renamer";
+    longDescription = ''
+      FileBot is the ultimate tool for organizing and renaming your Movies, TV
+      Shows and Anime as well as fetching subtitles and artwork. It's smart and
+      just works.
+    '';
+    homepage = "https://filebot.net";
+    changelog = "https://www.filebot.net/forums/viewforum.php?f=7";
+    license = licenses.unfreeRedistributable;
+    maintainers = with maintainers; [ gleber felschr ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index c027cfbeca5..27cb10ff727 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1945,6 +1945,8 @@ in
 
   filebench = callPackage ../tools/misc/filebench { };
 
+  filebot = callPackage ../applications/video/filebot { };
+
   fileshare = callPackage ../servers/fileshare {};
 
   fileshelter = callPackage ../servers/web-apps/fileshelter { };