Merge branch 'tomahawk'.

Adds the Tomahawk music player (https://www.tomahawk-player.org/) in
version 0.8.1 and all its required and optional dependencies.

* tomahawk:
  tomahawk: Add new package, version 0.8.1.
  libjreen: Add new package, version 1.2.0.
  websocketpp: Add new package, version 0.4.0.
  lucenepp: Add new package, version 3.0.6.
  qtkeychain: Add new package, version 0.4.0.
  libechonest: Add new package, version 2.3.0.
  quazip: Use qt instead of qt5 for refering to Qt.

pkgs/applications/audio/tomahawk/default.nix

@@ -0,0 +1,46 @@
+{ stdenv, fetchurl, cmake, pkgconfig, attica, boost, gnutls, libechonest
+, liblastfm, lucenepp, phonon, qca2, qjson, qt4, qtkeychain, quazip, sparsehash
+, taglib, websocketpp
+
+, enableXMPP      ? true,  libjreen     ? null
+, enableKDE       ? false, kdelibs      ? null
+, enableTelepathy ? false, telepathy_qt ? null
+}:
+
+assert enableXMPP      -> libjreen     != null;
+assert enableKDE       -> kdelibs      != null;
+assert enableTelepathy -> telepathy_qt != null;
+
+let
+  quazipQt4 = quazip.override { qt = qt4; };
+in stdenv.mkDerivation rec {
+  name = "tomahawk-${version}";
+  version = "0.8.1";
+
+  src = fetchurl {
+    url = "http://download.tomahawk-player.org/tomahawk-0.8.1.tar.bz2";
+    sha256 = "0ca6fah30a2s8nnlryav95wyzhwys1ikjfwakrqf2hb0y5aczdpw";
+  };
+
+  cmakeFlags = [
+    "-DLUCENEPP_INCLUDE_DIR=${lucenepp}/include"
+    "-DLUCENEPP_LIBRARY_DIR=${lucenepp}/lib"
+  ];
+
+  buildInputs = [
+    cmake pkgconfig attica boost gnutls libechonest liblastfm lucenepp phonon
+    qca2 qjson qt4 qtkeychain quazipQt4 sparsehash taglib websocketpp
+  ] ++ stdenv.lib.optional enableXMPP      libjreen
+    ++ stdenv.lib.optional enableKDE       kdelibs
+    ++ stdenv.lib.optional enableTelepathy telepathy_qt;
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    description = "A multi-source music player";
+    homepage = "http://tomahawk-player.org/";
+    license = licenses.gpl3Plus;
+    platforms = platforms.all;
+    maintainers = [ maintainers.aszlig ];
+  };
+}

pkgs/development/libraries/libechonest/default.nix

@@ -0,0 +1,20 @@
+{ stdenv, fetchurl, cmake, qt4, qjson, doxygen, boost }:
+
+stdenv.mkDerivation rec {
+  name = "libechonest-${version}";
+  version = "2.3.0";
+
+  src = fetchurl {
+    url = "http://files.lfranchi.com/${name}.tar.bz2";
+    sha1 = "cf1b279c96f15c87c36fdeb23b569a60cdfb01db";
+  };
+
+  buildInputs = [ cmake qt4 qjson doxygen boost ];
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "A C++/Qt wrapper around the Echo Nest API";
+    homepage = "http://projects.kde.org/projects/playground/libs/libechonest";
+    license = stdenv.lib.licenses.gpl2Plus;
+  };
+}

pkgs/development/libraries/libjreen/default.nix

@@ -0,0 +1,20 @@
+{ stdenv, fetchurl, cmake, qt4, pkgconfig, gsasl }:
+
+stdenv.mkDerivation rec {
+  name = "libjreen-${version}";
+  version = "1.2.0";
+
+  src = fetchurl {
+    url = "https://qutim.org/dwnl/73/${name}.tar.bz2";
+    sha256 = "14nwwk40xx8w6x7yaysgcr0lgzhs7l064f7ikp32s5y9a8mmp582";
+  };
+
+  buildInputs = [ cmake qt4 pkgconfig gsasl ];
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "C++ Jabber library using Qt framework";
+    homepage = "https://qutim.org/jreen/";
+    license = stdenv.lib.licenses.gpl2Plus;
+  };
+}

pkgs/development/libraries/lucene++/default.nix

@@ -0,0 +1,46 @@
+{ stdenv, fetchurl, fetchpatch, cmake, boost, gtest }:
+
+stdenv.mkDerivation rec {
+  name = "lucene++-${version}";
+  version = "3.0.6";
+
+  src = fetchurl {
+    url = "https://github.com/luceneplusplus/LucenePlusPlus/"
+        + "archive/rel_${version}.tar.gz";
+    sha256 = "068msvh05gsbfj1wwdqj698kxxfjdqy8zb6pqvail3ayjfj94w1y";
+  };
+
+  patches = let
+    baseurl = "https://github.com/luceneplusplus/LucenePlusPlus";
+  in [
+    (fetchpatch {
+      url = "${baseurl}/pull/62.diff";
+      sha256 = "0v314877mjb0hljg4mcqi317m1p1v27rgsgf5wdr9swix43vmhgw";
+    })
+    (fetchpatch {
+      url = "${baseurl}/commit/994f03cf736229044a168835ae7387696041658f.diff";
+      sha256 = "0fcm5b87nxw062wjd7b4qrfcwsyblmcw19s64004pklj9grk30zz";
+    })
+  ];
+
+  postPatch = ''
+    sed -i -e '/Subversion *REQUIRED/d' \
+           -e '/include.*CMakeExternal/d' \
+           CMakeLists.txt
+    # not using -f because we want it to fail for the next release
+    rm CMakeExternal.txt
+  '';
+
+  cmakeFlags = [ "-DGTEST_INCLUDE_DIR=${gtest}/include" ];
+  buildInputs = [ cmake boost gtest ];
+
+  enableParallelBuilding = true;
+  doCheck = true;
+  checkTarget = "test";
+
+  meta = {
+    description = "C++ port of the popular Java Lucene search engine";
+    homepage = "https://github.com/luceneplusplus/LucenePlusPlus";
+    license = with stdenv.lib.licenses; [ asl20 lgpl3Plus ];
+  };
+}

pkgs/development/libraries/qtkeychain/default.nix

@@ -0,0 +1,23 @@
+{ stdenv, fetchFromGitHub, cmake, qt4 }:
+
+stdenv.mkDerivation rec {
+  name = "qtkeychain-${version}";
+  version = "0.4.0";
+
+  src = fetchFromGitHub {
+    owner = "frankosterfeld";
+    repo = "qtkeychain";
+    rev = "v${version}";
+    sha256 = "10msaylisbwmgpwd59vr4dfgml75kji8mlfwnwq8yp29jikj5amq";
+  };
+
+  cmakeFlags = [ "-DQT_TRANSLATIONS_DIR=$out/share/qt/translations" ];
+
+  buildInputs = [ cmake qt4 ];
+
+  meta = {
+    description = "Platform-independent Qt API for storing passwords securely";
+    homepage = "https://github.com/frankosterfeld/qtkeychain";
+    license = stdenv.lib.licenses.BSD3;
+  };
+}

pkgs/development/libraries/quazip/default.nix

@@ -1,4 +1,4 @@
-{ fetchurl, stdenv, zip, zlib, qt5 }:
+{ fetchurl, stdenv, zip, zlib, qt }:
 
 stdenv.mkDerivation rec {
   name = "quazip-0.7";
@@ -12,7 +12,7 @@ stdenv.mkDerivation rec {
 
   installFlags = "INSTALL_ROOT=$(out)";
 
-  buildInputs = [ zlib qt5 ];
+  buildInputs = [ zlib qt ];
 
   meta = {
     description = "Provides access to ZIP archives from Qt programs";

pkgs/development/libraries/websocket++/default.nix

@@ -0,0 +1,21 @@
+{ stdenv, fetchFromGitHub, cmake }:
+
+stdenv.mkDerivation rec {
+  name = "websocket++-${version}";
+  version = "0.4.0";
+
+  src = fetchFromGitHub {
+    owner = "zaphoyd";
+    repo = "websocketpp";
+    rev = version;
+    sha256 = "1n6j0dh3qpis0f7crd49a2nhxd5459h0blch408z3kwlasx2g0i5";
+  };
+
+  buildInputs = [ cmake ];
+
+  meta = {
+    homepage = "http://www.zaphoyd.com/websocketpp/";
+    description = "C++/Boost Asio based websocket client/server library";
+    license = stdenv.lib.licenses.BSD3;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -5757,6 +5757,8 @@ let
 
   libe-book = callPackage ../development/libraries/libe-book {};
 
+  libechonest = callPackage ../development/libraries/libechonest { };
+
   libev = builderDefsPackage ../development/libraries/libev { };
 
   libevent14 = callPackage ../development/libraries/libevent/1.4.nix { };
@@ -5928,6 +5930,8 @@ let
     libtool = libtool_1_5;
   };
 
+  libjreen = callPackage ../development/libraries/libjreen { };
+
   libjson_rpc_cpp = callPackage ../development/libraries/libjson-rpc-cpp { };
 
   libkate = callPackage ../development/libraries/libkate { };
@@ -6596,7 +6600,9 @@ let
 
   qoauth = callPackage ../development/libraries/qoauth { };
 
-  quazip = callPackage ../development/libraries/quazip { };
+  quazip = callPackage ../development/libraries/quazip {
+    qt = qt5;
+  };
 
   qt3 = callPackage ../development/libraries/qt-3 {
     openglSupport = mesaSupported;
@@ -6668,6 +6674,8 @@ let
     qtLib = qt48.override { developerBuild = true; };
   };
 
+  qtkeychain = callPackage ../development/libraries/qtkeychain { };
+
   qtscriptgenerator = callPackage ../development/libraries/qtscriptgenerator { };
 
   quesoglc = callPackage ../development/libraries/quesoglc { };
@@ -6999,6 +7007,8 @@ let
     enableIntrospection = false;
   };
 
+  websocketpp = callPackage ../development/libraries/websocket++ { };
+
   wildmidi = callPackage ../development/libraries/wildmidi { };
 
   wvstreams = callPackage ../development/libraries/wvstreams { };
@@ -7197,6 +7207,8 @@ let
 
   lucene = callPackage ../development/libraries/java/lucene { };
 
+  lucenepp = callPackage ../development/libraries/lucene++ { };
+
   mockobjects = callPackage ../development/libraries/java/mockobjects { };
 
   saxon = callPackage ../development/libraries/java/saxon { };
@@ -10780,6 +10792,13 @@ let
 
   todo-txt-cli = callPackage ../applications/office/todo.txt-cli { };
 
+  tomahawk = callPackage ../applications/audio/tomahawk {
+    inherit (pkgs.kde4) kdelibs;
+    enableXMPP      = config.tomahawk.enableXMPP      or true;
+    enableKDE       = config.tomahawk.enableKDE       or false;
+    enableTelepathy = config.tomahawk.enableTelepathy or false;
+  };
+
   torchat = callPackage ../applications/networking/instant-messengers/torchat {
     wrapPython = pythonPackages.wrapPython;
   };