boost: updated to version 1.40.0

* Dropped classr.patch; it no longer applies to this version.

 * The "configure" script has been renamed to "bootstrap.sh".

 * The bootstrapping process generates no Makefile anymore; the build
   expression has to call bjam directly to build the libraries.

 * Perform build and install phase in one execution of bjam. This is a
   lot faster, because bjam won't check the dependencies twice.

svn path=/nixpkgs/trunk/; revision=17471

pkgs/development/libraries/boost/1.40.0.nix

@@ -0,0 +1,48 @@
+{ stdenv, fetchurl, icu, expat, zlib, bzip2, python
+, enableRelease ? true
+, enableDebug ? false
+, enableSingleThreaded ? false
+, enableMultiThreaded ? true
+, enableShared ? true
+, enableStatic ? false
+}:
+
+let
+
+  variant = stdenv.lib.concatStringsSep ","
+    (stdenv.lib.optional enableRelease "release" ++
+     stdenv.lib.optional enableDebug "debug");
+
+  threading = stdenv.lib.concatStringsSep ","
+    (stdenv.lib.optional enableSingleThreaded "single" ++
+     stdenv.lib.optional enableMultiThreaded "multi");
+
+  link = stdenv.lib.concatStringsSep ","
+    (stdenv.lib.optional enableShared "shared" ++
+     stdenv.lib.optional enableStatic "static");
+
+in
+
+stdenv.mkDerivation {
+  name = "boost-1.40.0";
+
+  meta = {
+    homepage = "http://boost.org/";
+    description = "Boost C++ Library Collection";
+    license = "boost-license";
+  };
+
+  src = fetchurl {
+    url = "mirror://sourceforge/boost/boost_1_40_0.tar.bz2";
+    sha256 = "032k85lfqg9zlx7m4acqy8x4r8950llnxprzjaj6fw2qkcilmkrn";
+  };
+
+  buildInputs = [icu expat zlib bzip2 python];
+
+  configureScript = "./bootstrap.sh";
+  configureFlags = "--with-icu=${icu} --with-python=${python}/bin/python";
+
+  buildPhase = "./bjam -sEXPAT_INCLUDE=${expat}/include -sEXPAT_LIBPATH=${expat}/lib --layout=system variant=${variant} threading=${threading} link=${link} install";
+
+  installPhase = ":";
+}

pkgs/top-level/all-packages.nix

@@ -2932,7 +2932,7 @@ let
     inherit fetchurl stdenv icu expat zlib bzip2 python;
   };
 
-  boost = makeOverridable (import ../development/libraries/boost/1.38.0.nix) {
+  boost = makeOverridable (import ../development/libraries/boost/1.40.0.nix) {
     inherit fetchurl stdenv icu expat zlib bzip2 python;
   };