Merge pull request #4282 from sztupi/crashplan

Crashplan

OK, it is an external service with unfree client, so let's declare that ensuring usability of the service is not our headache.

lib/maintainers.nix

@@ -139,6 +139,7 @@
   skeidel = "Sven Keidel <svenkeidel@gmail.com>";
   smironov = "Sergey Mironov <ierton@gmail.com>";
   sprock = "Roger Mason <rmason@mun.ca>";
+  sztupi = "Attila Sztupak <attila.sztupak@gmail.com>";
   tailhook = "Paul Colomiets <paul@colomiets.name>";
   thammers = "Tobias Hammerschmidt <jawr@gmx.de>";
   the-kenny = "Moritz Ulrich <moritz@tarn-vedra.de>";

nixos/modules/module-list.nix

@@ -92,6 +92,7 @@
   ./services/audio/mopidy.nix
   ./services/backup/almir.nix
   ./services/backup/bacula.nix
+  ./services/backup/crashplan.nix
   ./services/backup/mysql-backup.nix
   ./services/backup/postgresql-backup.nix
   ./services/backup/rsnapshot.nix

nixos/modules/services/backup/crashplan.nix

@@ -0,0 +1,63 @@
+{ config, pkgs, ... }:
+
+let
+  cfg = config.services.crashplan;
+  crashplan = pkgs.crashplan;
+  varDir = "/var/lib/crashplan";
+in
+
+with pkgs.lib;
+
+{
+  options = {
+    services.crashplan = {
+      enable = mkOption {
+        default = false;
+        type = types.bool;
+        description = ''
+          Starts crashplan background service.
+        '';
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    environment.systemPackages = [ crashplan ];
+
+    systemd.services.crashplan = {
+      description = "CrashPlan Backup Engine";
+
+      wantedBy = [ "multi-user.target" ];
+      after    = [ "network.target" ];
+
+      preStart = ''
+        ensureDir() {
+          dir=$1
+          mode=$2
+
+          if ! test -e $dir; then
+            ${pkgs.coreutils}/bin/mkdir -m $mode -p $dir
+          elif [ "$(${pkgs.coreutils}/bin/stat -c %a $dir)" != "$mode" ]; then
+            ${pkgs.coreutils}/bin/chmod $mode $dir
+          fi
+        }
+
+        ensureDir ${crashplan.vardir} 755
+        ensureDir ${crashplan.vardir}/conf 700
+        ensureDir ${crashplan.manifestdir} 700
+        ensureDir ${crashplan.vardir}/cache 700
+        ensureDir ${crashplan.vardir}/backupArchives 700
+        ensureDir ${crashplan.vardir}/log 777
+      '';
+
+      serviceConfig = {
+        Type = "forking";
+        EnvironmentFile = "${crashplan}/bin/run.conf";
+        ExecStart = "${crashplan}/bin/CrashPlanEngine start";
+        ExecStop = "${crashplan}/bin/CrashPlanEngine stop";
+        PIDFile = "${crashplan.vardir}/CrashPlanEngine.pid";
+        WorkingDirectory = crashplan;
+      };
+    };
+  };
+}

pkgs/applications/backup/crashplan/CrashPlanEngine.patch

@@ -0,0 +1,37 @@
+--- ./scripts/CrashPlanEngine	2014-02-19 23:17:19.000000000 +0000
++++ ./scripts/CrashPlanEngine.1	2014-07-24 17:36:37.330333581 +0100
+@@ -11,7 +11,7 @@
+ 	
+ 	cd $TARGETDIR
+ 		
+-	nice -n 19 $JAVACOMMON $SRV_JAVA_OPTS -classpath $FULL_CP com.backup42.service.CPService > $TARGETDIR/log/engine_output.log 2> $TARGETDIR/log/engine_error.log & 
++	nice -n 19 $JAVACOMMON $SRV_JAVA_OPTS -classpath $FULL_CP com.backup42.service.CPService > $VARDIR/log/engine_output.log 2> $VARDIR/log/engine_error.log & 
+ 	
+ 	if [[ $! -gt 0 ]]; then
+ 		echo $! > $PIDFILE
+@@ -26,7 +26,7 @@
+ 
+ 	echo "Using Ubuntu 9.04 startup"
+ 	
+-	start-stop-daemon -v --pidfile $PIDFILE --make-pidfile --background --chdir $TARGETDIR --start --nicelevel 19 --exec $JAVACOMMON -- $SRV_JAVA_OPTS -classpath $FULL_CP com.backup42.service.CPService > $TARGETDIR/log/engine_output.log 2> $TARGETDIR/log/engine_error.log
++	start-stop-daemon -v --pidfile $PIDFILE --make-pidfile --background --chdir $TARGETDIR --start --nicelevel 19 --exec $JAVACOMMON -- $SRV_JAVA_OPTS -classpath $FULL_CP com.backup42.service.CPService > $VARDIR/log/engine_output.log 2> $VARDIR/log/engine_error.log
+ 	
+ 	# This test isn't as useful as one might like; start-stop-daemon can't accurately report the state of child processes when --background is used.
+ 	# We use this mainly to report the specific error value returned by start-stop-daemon if something goes wrong, but be aware that a return value
+@@ -91,7 +91,6 @@
+ DESC="CrashPlan Engine"
+ NAME=CrashPlanEngine
+ DAEMON=$TARGETDIR/lib/com.backup42.desktop.jar
+-PIDFILE="$TARGETDIR/${NAME}.pid"
+ 
+ if [[ -f $TARGETDIR/install.vars ]]; then
+ 	. $TARGETDIR/install.vars
+@@ -100,6 +99,8 @@
+ 	exit 1
+ fi
+ 
++PIDFILE="$VARDIR/${NAME}.pid"
++
+ if [[ ! -f $DAEMON ]]; then
+ 	echo "Could not find JAR file $DAEMON"
+ 	exit 0

pkgs/applications/backup/crashplan/default.nix

@@ -0,0 +1,78 @@
+{ stdenv, fetchurl, makeWrapper, jre, cpio, gawk, gnugrep, gnused, procps, swt, gtk2, glib, libXtst }:
+
+let version = "3.6.3";
+
+in stdenv.mkDerivation rec {
+  name = "crashplan-${version}";
+
+  crashPlanArchive = fetchurl {
+    url = "http://download.crashplan.com/installs/linux/install/CrashPlan/CrashPlan_${version}_Linux.tgz";
+    sha256 = "0v01fzc62bxr6lpamnxg1nb7vh4a8ky6mahbq76kmjxfqv7q0mb0";
+  };
+
+  srcs = [ crashPlanArchive ];
+
+  meta = with stdenv.lib; {
+    description = "An online/offline backup solution";
+    homepage = "http://www.crashplan.org";
+    license = licenses.unfree;
+    maintainers = with maintainers; [ sztupi ];
+  };
+
+  buildInputs = [ makeWrapper cpio ];
+
+  vardir = "/var/lib/crashplan";
+
+  manifestdir = "${vardir}/manifest";
+
+  patches = [ ./CrashPlanEngine.patch ];
+
+  installPhase = ''
+    mkdir $out
+    zcat -v CrashPlan_${version}.cpi | (cd $out; cpio -i -d -v --no-preserve-owner)
+
+    # sed -i "s|<manifestPath>manifest</manifestPath>|<manifestPath>${manifestdir}</manifestPath>|g" $out/conf/default.service.xml
+
+    # Fix for encoding troubles (CrashPlan ticket 178827)
+    # Make sure the daemon is running using the same localization as
+    # the (installing) user
+    echo "" >> run.conf
+    echo "export LC_ALL=en_US.UTF-8" >> run.conf
+
+    install -d -m 755 unpacked $out
+
+    install -D -m 644 EULA.txt $out/EULA.txt
+    install -D -m 644 run.conf $out/bin/run.conf
+    install -D -m 755 scripts/CrashPlanDesktop $out/bin/CrashPlanDesktop
+    install -D -m 755 scripts/CrashPlanEngine $out/bin/CrashPlanEngine
+
+    rm -r $out/log
+    ln -s $vardir/log $out/log
+    ln -s $vardir/cache $out/cache
+    ln -s $vardir/backupArchives $out/backupArchives
+    ln -s $vardir/conf/service.model $out/conf/service.model
+    ln -s $vardir/conf/my.service.xml $out/conf/my.service.xml
+
+    echo "JAVACOMMON=${jre}/bin/java" > $out/install.vars
+    echo "APP_BASENAME=CrashPlan" >> $out/install.vars
+    echo "TARGETDIR=$out" >> $out/install.vars
+    echo "BINSDIR=$out/bin" >> $out/install.vars
+    echo "MANIFESTDIR=${manifestdir}" >> $out/install.vars
+    echo "VARDIR=${vardir}" >> $out/install.vars
+    echo "INITDIR=" >> $out/install.vars
+    echo "RUNLVLDIR=" >> $out/install.vars
+    echo "INSTALLDATE=" >> $out/install.vars
+  '';
+
+  postFixup = ''
+    for f in $out/bin/CrashPlanDesktop $out/bin/CrashPlanEngine; do
+      echo "substitutions in $f"
+      substituteInPlace $f --replace /bin/ps  ${procps}/bin/ps
+      substituteInPlace $f --replace awk      ${gawk}/bin/awk
+      substituteInPlace $f --replace sed      ${gnused}/bin/sed
+      substituteInPlace $f --replace grep     ${gnugrep}/bin/grep
+    done
+
+    wrapProgram $out/bin/CrashPlanDesktop --prefix LD_LIBRARY_PATH ":" "${gtk2}/lib:${glib}/lib:${libXtst}/lib"
+  '';
+}

pkgs/top-level/all-packages.nix

@@ -12273,6 +12273,8 @@ let
 
   cups_pdf_filter = callPackage ../misc/cups/pdf-filter.nix { };
 
+  crashplan = callPackage ../applications/backup/crashplan { };
+
   gutenprint = callPackage ../misc/drivers/gutenprint { };
 
   gutenprintBin = callPackage ../misc/drivers/gutenprint/bin.nix { };