From 6a981b514198d9b615be065e7b7fa4a2adbeb890 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?=E5=AE=8B=E6=96=87=E6=AD=A6?= <iyzsong@gmail.com>
Date: Sat, 22 Mar 2014 22:33:35 +0800
Subject: [PATCH] add pitivi 0.93

---
 pkgs/applications/video/pitivi/default.nix | 52 ++++++++++++++++++++++
 pkgs/top-level/all-packages.nix            |  5 +++
 2 files changed, 57 insertions(+)
 create mode 100644 pkgs/applications/video/pitivi/default.nix

diff --git a/pkgs/applications/video/pitivi/default.nix b/pkgs/applications/video/pitivi/default.nix
new file mode 100644
index 00000000000..d6a0c0e5212
--- /dev/null
+++ b/pkgs/applications/video/pitivi/default.nix
@@ -0,0 +1,52 @@
+{ stdenv, fetchurl, pkgconfig, intltool, itstool, makeWrapper
+, pythonPackages, gst, clutter-gst, clutter-gtk
+, gobjectIntrospection, clutter, gtk3, librsvg
+}:
+
+let
+  version = "0.93";
+in stdenv.mkDerivation rec {
+  name = "pitivi-${version}";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/pitivi/${version}/${name}.tar.xz";
+    sha256 = "0z89dwrd7akhkap270i372yszqib8yqcymv78lhdmn3a8bsa7jhp";
+  };
+
+  meta = with stdenv.lib; {
+    description = "Non-Linear video editor utilizing the power of GStreamer";
+    homepage    = "http://pitivi.org/";
+    longDescription = ''
+      Pitivi is a video editor built upon the GStreamer Editing Services.
+      It aims to be an intuitive and flexible application
+      that can appeal to newbies and professionals alike.
+    '';
+    license     = licenses.lgpl21Plus;
+    platforms   = platforms.linux;
+    maintainers = with maintainers; [ iyzsong ];
+  };
+
+  nativeBuildInputs = [ pkgconfig intltool itstool makeWrapper ];
+
+  buildInputs = [
+    gobjectIntrospection clutter-gst clutter-gtk librsvg
+  ] ++ (with gst; [
+    gst-python gst-editing-services
+    gst-plugins-base gst-plugins-good
+    gst-plugins-bad gst-plugins-ugly gst-libav
+  ]) ++ (with pythonPackages; [
+    python pygobject3 pyxdg numpy pycairo sqlite3
+  ]);
+
+  postInstall = with stdenv.lib; with gst; let
+    libraryPath = makeLibraryPath [
+      gstreamer gst-editing-services
+      clutter-gst clutter-gtk clutter gtk3
+    ];
+  in ''
+    wrapProgram "$out/bin/pitivi" \
+      --set GDK_PIXBUF_MODULE_FILE "$GDK_PIXBUF_MODULE_FILE" \
+      --prefix LD_LIBRARY_PATH : "${libraryPath}" \
+      --prefix GST_PLUGIN_SYSTEM_PATH_1_0 : "$GST_PLUGIN_SYSTEM_PATH_1_0"
+  '';
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 10df9bbd986..dad2bf5056a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1630,6 +1630,11 @@ let
 
   parted = callPackage ../tools/misc/parted { hurd = null; };
 
+  pitivi = callPackage ../applications/video/pitivi {
+    gst = gst_all_1;
+    clutter-gtk = clutter_gtk;
+  };
+
   hurdPartedCross =
     if crossSystem != null && crossSystem.config == "i586-pc-gnu"
     then (makeOverridable