generators: add PLIST handling

/cc @LnL7 @3noch

lib/generators.nix

@@ -175,4 +175,52 @@ rec {
                          else "<λ:{${showFnas}}>"
     else abort "toPretty: should never happen (v = ${v})";
 
+  # PLIST handling
+
+  toPLIST = x: ''
+    <?xml version="1.0" encoding="UTF-8"?>
+    <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
+    <plist version="1.0">
+  '' + pprExpr "" x
+     + "\n</plist>";
+
+  pprExpr = ind: x: with builtins;
+    if isNull x then "" else
+    if isBool x then pprBool ind x else
+    if isInt x then pprInt ind x else
+    if isString x then pprStr ind x else
+    if isList x then pprList ind x else
+    if isAttrs x then pprAttrs ind x else
+    throw "invalid plist type";
+
+  pprLiteral = ind: x: ind + x;
+
+  pprBool = ind: x: pprLiteral ind  (if x then "<true/>" else "<false/>");
+  pprInt = ind: x: pprLiteral ind "<integer>${toString x}</integer>";
+  pprStr = ind: x: pprLiteral ind "<string>${x}</string>";
+  pprKey = ind: x: pprLiteral ind "<key>${x}</key>";
+
+  pprIndent = ind: pprExpr "\t${ind}";
+
+  pprItem = ind: libStr.concatMapStringsSep "\n" (pprIndent ind);
+
+  pprList = ind: x: libStr.concatStringsSep "\n" [
+    (pprLiteral ind "<array>")
+    (pprItem ind x)
+    (pprLiteral ind "</array>")
+  ];
+
+  pprAttrs = ind: x: libStr.concatStringsSep "\n" [
+    (pprLiteral ind "<dict>")
+    (pprAttr ind x)
+    (pprLiteral ind "</dict>")
+  ];
+
+  attrFilter = name: value: name != "_module" && value != null;
+
+  pprAttr = ind: x: libStr.concatStringsSep "\n" (lib.flatten (lib.mapAttrsToList (name: value: lib.optional (attrFilter name value) [
+    (pprKey "\t${ind}" name)
+    (pprExpr "\t${ind}" value)
+  ]) x));
+
 }