From 24dc9d7160823b89a9af3acad072b972900479ff Mon Sep 17 00:00:00 2001
From: lassulus <lass@aidsballs.de>
Date: Fri, 12 Jun 2015 13:29:12 +0200
Subject: [PATCH] add pkgs: fmod42416

---
 pkgs/development/libraries/fmod/4.24.16.nix | 50 +++++++++++++++++++++
 pkgs/top-level/all-packages.nix             |  2 +
 2 files changed, 52 insertions(+)
 create mode 100644 pkgs/development/libraries/fmod/4.24.16.nix

diff --git a/pkgs/development/libraries/fmod/4.24.16.nix b/pkgs/development/libraries/fmod/4.24.16.nix
new file mode 100644
index 00000000000..d1768d656b4
--- /dev/null
+++ b/pkgs/development/libraries/fmod/4.24.16.nix
@@ -0,0 +1,50 @@
+{ stdenv, fetchurl }:
+
+assert (stdenv.system == "x86_64-linux") || (stdenv.system == "i686-linux");
+let
+  bits = stdenv.lib.optionalString (stdenv.system == "x86_64-linux") "64";
+
+  libPath = stdenv.lib.makeLibraryPath
+    [ stdenv.cc.libc stdenv.cc.cc ] + ":${stdenv.cc.cc}/lib64";
+  patchLib = x: "patchelf --set-rpath ${libPath} ${x}";
+
+  src =
+    (if (bits == "64") then
+      fetchurl {
+        url = "http://www.fmod.org/download/fmodex/api/Linux/fmodapi42416linux64.tar.gz";
+        sha256 = "0hkwlzchzzgd7fanqznbv5bs53z2qy8iiv9l2y77l4sg1jwmlm6y";
+      }
+    else
+      fetchurl {
+        url = "http://www.fmod.org/download/fmodex/api/Linux/fmodapi42416linux.tar.gz";
+        sha256 = "13diw3ax2slkr99mwyjyc62b8awc30k0z08cvkpk2p3i1j6f85m5";
+      }
+    );
+in
+stdenv.mkDerivation rec {
+  inherit src;
+
+  name    = "fmod-${version}";
+  version = "4.24.16";
+
+  dontStrip = true;
+  buildPhase = "true";
+  installPhase = ''
+    mkdir -p $out/lib $out/include/fmodex
+
+    cd api/inc && cp * $out/include/fmodex && cd ../lib
+    cp libfmodex${bits}-${version}.so $out/lib/libfmodex.so
+    cp libfmodex${bits}L-${version}.so $out/lib/libfmodexL.so
+
+    ${patchLib "$out/lib/libfmodex.so"}
+    ${patchLib "$out/lib/libfmodexL.so"}
+  '';
+
+  meta = {
+    description = "Programming library and toolkit for the creation and playback of interactive audio";
+    homepage    = "http://www.fmod.org/";
+    license     = stdenv.lib.licenses.unfreeRedistributable;
+    platforms   = stdenv.lib.platforms.linux;
+    maintainers = [ stdenv.lib.maintainers.lassulus ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 46f59d43fc1..f40d7fc466f 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -6065,6 +6065,8 @@ let
 
   fmod = callPackage ../development/libraries/fmod { };
 
+  fmod42416 = callPackage ../development/libraries/fmod/4.24.16.nix { };
+
   freeimage = callPackage ../development/libraries/freeimage { };
 
   freetts = callPackage ../development/libraries/freetts { };