From 22080d19519c91c3e72d69a8b94f939ceb2930c1 Mon Sep 17 00:00:00 2001
From: Tobias Geerinckx-Rice <tobias.geerinckx.rice@gmail.com>
Date: Fri, 6 Mar 2015 01:26:15 +0100
Subject: [PATCH] Add x2goclient 4.0.3.2

Thanks to Christoph-Simon Senjak <c s s at u x u l dot d e>
---
 .../networking/remote/x2goclient/default.nix  | 37 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 39 insertions(+)
 create mode 100644 pkgs/applications/networking/remote/x2goclient/default.nix

diff --git a/pkgs/applications/networking/remote/x2goclient/default.nix b/pkgs/applications/networking/remote/x2goclient/default.nix
new file mode 100644
index 00000000000..9ce00facfbb
--- /dev/null
+++ b/pkgs/applications/networking/remote/x2goclient/default.nix
@@ -0,0 +1,37 @@
+{ stdenv, fetchurl, cups, libssh, libXpm, nxproxy, openldap, makeWrapper, qt4 }:
+
+let version = "4.0.3.2"; in
+stdenv.mkDerivation rec {
+  name = "x2goclient-${version}";
+
+  src = fetchurl {
+    url = "http://code.x2go.org/releases/source/x2goclient/${name}.tar.gz";
+    sha256 = "0vqcz9kmnbvlj8kns68zl60019fdz97rydz4wsgnsgdf7r370npn";
+  };
+
+  meta = with stdenv.lib; {
+    description = "Graphical NoMachine NX3 remote desktop client";
+    homepage = http://x2go.org/;
+    license = with licenses; gpl2;
+    platforms = with platforms; linux;
+    maintainers = with maintainers; [ nckx ];
+  };
+
+  buildInputs = [ cups libssh libXpm nxproxy openldap makeWrapper qt4 ];
+
+  patchPhase = ''
+     substituteInPlace Makefile \
+       --replace "lrelease-qt4" "${qt4}/bin/lrelease" \
+       --replace "qmake-qt4" "${qt4}/bin/qmake" \
+       --replace "-o root -g root" ""
+  '';
+
+  makeFlags = [ "PREFIX=$(out)" "ETCDIR=$(out)/etc" ];
+
+  enableParallelBuild = true;
+
+  installTargets = [ "install_client" "install_man" ];
+  postInstall = ''
+    wrapProgram "$out/bin/x2goclient" --suffix PATH : "${nxproxy}/bin";
+  '';
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 3ca70fbda4e..b3560d5f442 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -12010,6 +12010,8 @@ let
 
   x11vnc = callPackage ../tools/X11/x11vnc { };
 
+  x2goclient = callPackage ../applications/networking/remote/x2goclient { };
+
   x2vnc = callPackage ../tools/X11/x2vnc { };
 
   xaos = builderDefsPackage (import ../applications/graphics/xaos) {