pythonPackages.graphite_api: move expression

According to the current convention python packages should live in
`pkgs/development/python-modules`. As I altered the `graphite_api`
expression previously in d3d1b88873 I decided to move it as well.

Additionally I applied some minor refactorings:

* use `fetchFromGitHub` instead of `fetchgit`.

* use `checkInputs` for test dependencies

* got rid of fixed points

* applied patch which supports flask-caching to 1.3.1 using `git apply
  -3`

pkgs/development/python-modules/graphite-api/default.nix

@@ -0,0 +1,45 @@
+{ buildPythonPackage, fetchFromGitHub, lib, flask, flask-caching, cairocffi, pyparsing, pytz, pyyaml
+, raven, six, structlog, tzlocal, nose, mock, cairo, isPyPy
+}:
+
+buildPythonPackage rec {
+  pname = "graphite-api";
+  version = "1.1.3";
+
+  disabled = isPyPy;
+
+  src = fetchFromGitHub {
+    owner = "brutasse";
+    repo = "graphite-api";
+    rev = version;
+    sha256 = "0sz3kav2024ms2z4q03pigcf080gsr5v774z9bp3zw29k2p47ass";
+  };
+
+  # https://github.com/brutasse/graphite-api/pull/239 rebased onto 1.1.3
+  patches = [ ./flask-caching-rebased.patch ];
+
+  checkPhase = "nosetests";
+
+  propagatedBuildInputs = [
+    flask
+    flask-caching
+    cairocffi
+    pyparsing
+    pytz
+    pyyaml
+    raven
+    six
+    structlog
+    tzlocal
+  ];
+
+  checkInputs = [ nose mock ];
+
+  LD_LIBRARY_PATH = "${cairo.out}/lib";
+
+  meta = with lib; {
+    description = "Graphite-web, without the interface. Just the rendering HTTP API";
+    homepage = https://github.com/brutasse/graphite-api;
+    license = licenses.asl20;
+  };
+}