From e697f10fc4e5343c9fc3c253efb910fecb6f84da Mon Sep 17 00:00:00 2001
From: Christopher Singley <csingley@gmail.com>
Date: Sun, 29 Oct 2017 19:28:16 -0500
Subject: [PATCH 1/2] PlexPy: init at 1.4.25

---
 lib/maintainers.nix             |  1 +
 pkgs/servers/plexpy/default.nix | 41 +++++++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix |  2 ++
 3 files changed, 44 insertions(+)
 create mode 100644 pkgs/servers/plexpy/default.nix

diff --git a/lib/maintainers.nix b/lib/maintainers.nix
index 7c3a845c00c..dc2281401e0 100644
--- a/lib/maintainers.nix
+++ b/lib/maintainers.nix
@@ -136,6 +136,7 @@
   cryptix = "Henry Bubert <cryptix@riseup.net>";
   CrystalGamma = "Jona Stubbe <nixos@crystalgamma.de>";
   cstrahan = "Charles Strahan <charles@cstrahan.com>";
+  csingley = "Christopher Singley <csingley@gmail.com>";
   cwoac = "Oliver Matthews <oliver@codersoffortune.net>";
   DamienCassou = "Damien Cassou <damien@cassou.me>";
   danbst = "Danylo Hlynskyi <abcz2.uprola@gmail.com>";
diff --git a/pkgs/servers/plexpy/default.nix b/pkgs/servers/plexpy/default.nix
new file mode 100644
index 00000000000..2875ecc5240
--- /dev/null
+++ b/pkgs/servers/plexpy/default.nix
@@ -0,0 +1,41 @@
+{stdenv, fetchFromGitHub, python}:
+
+stdenv.mkDerivation rec {
+  version = "1.4.25";
+  pname = "plexpy";
+  name = "${pname}-${version}";
+
+  src = fetchFromGitHub {
+    owner = "JonnyWong16";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "0a4ynrfamlwkgqil4n61v47p21czxpjdzg0mias4kdjam2nnwnjx";
+  };
+
+  buildPhase = ":";
+
+  installPhase = ''
+    mkdir -p $out
+    cp -R * $out/
+
+    # Remove superfluous Python checks from main script;
+    # prepend shebang
+    echo "#!${python.interpreter}" > $out/PlexPy.py
+    tail -n +7 PlexPy.py >> $out/PlexPy.py
+
+    mkdir $out/bin
+    # Can't just symlink to the main script, since it uses __file__ to
+    # import bundled packages and manage the service
+    echo "#!/bin/bash" > $out/bin/plexpy
+    echo "$out/PlexPy.py \$*" >> $out/bin/plexpy
+    chmod +x $out/bin/plexpy
+  '';
+
+  meta  = with stdenv.lib; {
+    description = "A Python based monitoring and tracking tool for Plex Media Server.";
+    homepage = http://jonnywong16.github.io/plexpy/;
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ csingley ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 596051f4ea7..762f217fcbe 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -3966,6 +3966,8 @@ with pkgs;
 
   plex = callPackage ../servers/plex { enablePlexPass = config.plex.enablePlexPass or false; };
 
+  plexpy = callPackage ../servers/plexpy { python = python2; };
+
   ploticus = callPackage ../tools/graphics/ploticus {
     libpng = libpng12;
   };

From 95dc36235ce21ab8563f1ba61a5d80e6c2ea9e3b Mon Sep 17 00:00:00 2001
From: Christopher Singley <csingley@gmail.com>
Date: Sun, 29 Oct 2017 19:29:25 -0500
Subject: [PATCH 2/2] PlexPy service

---
 nixos/modules/module-list.nix          |  1 +
 nixos/modules/services/misc/plexpy.nix | 81 ++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 nixos/modules/services/misc/plexpy.nix

diff --git a/nixos/modules/module-list.nix b/nixos/modules/module-list.nix
index 6f00a97dd3f..44bcec5aec2 100644
--- a/nixos/modules/module-list.nix
+++ b/nixos/modules/module-list.nix
@@ -328,6 +328,7 @@
   ./services/misc/parsoid.nix
   ./services/misc/phd.nix
   ./services/misc/plex.nix
+  ./services/misc/plexpy.nix
   ./services/misc/pykms.nix
   ./services/misc/radarr.nix
   ./services/misc/redmine.nix
diff --git a/nixos/modules/services/misc/plexpy.nix b/nixos/modules/services/misc/plexpy.nix
new file mode 100644
index 00000000000..df9f1258124
--- /dev/null
+++ b/nixos/modules/services/misc/plexpy.nix
@@ -0,0 +1,81 @@
+{ config, pkgs, lib, ... }:
+
+with lib;
+
+let
+  cfg = config.services.plexpy;
+in
+{
+  options = {
+    services.plexpy = {
+      enable = mkEnableOption "PlexPy Plex Monitor";
+
+      dataDir = mkOption {
+        type = types.str;
+        default = "/var/lib/plexpy";
+        description = "The directory where PlexPy stores its data files.";
+      };
+
+      configFile = mkOption {
+        type = types.str;
+        default = "/var/lib/plexpy/config.ini";
+        description = "The location of PlexPy's config file.";
+      };
+
+      port = mkOption {
+        type = types.int;
+        default = 8181;
+        description = "TCP port where PlexPy listens.";
+      };
+
+      user = mkOption {
+        type = types.str;
+        default = "plexpy";
+        description = "User account under which PlexPy runs.";
+      };
+
+      group = mkOption {
+        type = types.str;
+        default = "nogroup";
+        description = "Group under which PlexPy runs.";
+      };
+
+      package = mkOption {
+        type = types.package;
+        default = pkgs.plexpy;
+        defaultText = "pkgs.plexpy";
+        description = ''
+          The PlexPy package to use.
+        '';
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    systemd.services.plexpy = {
+      description = "PlexPy Plex Monitor";
+      after = [ "network.target" ];
+      wantedBy = [ "multi-user.target" ];
+      preStart = ''
+        test -d "${cfg.dataDir}" || {
+          echo "Creating initial PlexPy data directory in \"${cfg.dataDir}\"."
+          mkdir -p "${cfg.dataDir}"
+          chown ${cfg.user}:${cfg.group} "${cfg.dataDir}"
+        }
+     '';
+      serviceConfig = {
+        Type = "simple";
+        User = cfg.user;
+        Group = cfg.group;
+        PermissionsStartOnly = "true";
+        GuessMainPID = "false";
+        ExecStart = "${cfg.package}/bin/plexpy --datadir ${cfg.dataDir} --config ${cfg.configFile} --port ${toString cfg.port} --pidfile ${cfg.dataDir}/plexpy.pid --nolaunch";
+        Restart = "on-failure";
+      };
+    };
+
+    users.extraUsers = mkIf (cfg.user == "plexpy") {
+      plexpy = { group = cfg.group; uid = config.ids.uids.plexpy; };
+    };
+  };
+}