* Updated audacious to 2.3. Combined audacious and audacious-plugins

into one derivation so that it works out of the box - no need to set
  symlinks to the plugins in ~/.local/share/audacious.  There is
  really no reason to install those packages separately anyway, as
  audacious is useless without the plugins package.

svn path=/nixpkgs/trunk/; revision=21137

pkgs/applications/audio/audacious/default.nix

@@ -0,0 +1,54 @@
+{ stdenv, fetchurl, pkgconfig, glib, gtk, libmowgli, libmcs
+, gettext, dbus_glib, libxml2, libmad, xlibs, alsaLib, libogg
+, libvorbis, libcdio, libcddb, flac 
+}:
+
+stdenv.mkDerivation rec {
+  name = "audacious-2.3";
+  
+  src = fetchurl {
+    url = "http://distfiles.atheme.org/${name}.tgz";
+    sha256 = "0vs16y1vrlkzcbaw8imc36b9lncva69zkdkp38ikbidssiskm6xi";
+  };
+
+  pluginsSrc = fetchurl {
+    url = "http://distfiles.atheme.org/audacious-plugins-2.3.tgz";
+    sha256 = "0hdami52qpiyim3nz3qnml85wgjzpmx6g2wahfnsdvncmhm4v93x";
+  };
+  
+  # `--enable-amidiplug' is to prevent configure from looking in /proc/asound.
+  configureFlags = "--enable-amidiplug";
+  
+  buildInputs =
+    [ gettext pkgconfig glib gtk libmowgli libmcs libxml2 dbus_glib
+      libmad xlibs.libXcomposite libogg libvorbis flac alsaLib libcdio
+      libcddb
+    ];
+
+  # Here we build bouth audacious and audacious-plugins in one
+  # derivations, since they really expect to be in the same prefix.
+  # This is slighly tricky.
+  builder = builtins.toFile "builder.sh"
+    ''
+      # First build audacious.
+      (
+        source $stdenv/setup
+        genericBuild
+      )
+
+      # Then build the plugins.
+      (
+        buildNativeInputs="$out $buildNativeInputs" # to find audacious
+        source $stdenv/setup
+        rm -rfv audacious-*
+        src=$pluginsSrc
+        genericBuild
+      )
+    '';
+
+  meta = {
+    description = "Audacious, a media player forked from the Beep Media Player, which was itself an XMMS fork";
+    homepage = http://audacious-media-player.org/;
+    maintainers = [ stdenv.lib.maintainers.eelco ];
+  };
+}

pkgs/applications/audio/audacious/player.nix

@@ -1,32 +0,0 @@
-{ stdenv, fetchurl, pkgconfig, glib, gtk, libmowgli
-, libglade, libmcs, gettext, xlibs, dbus_glib
-}:
-
-stdenv.mkDerivation {
-  name = "audacious-1.5.1";
-  
-  src = fetchurl {
-    url = http://distfiles.atheme.org/audacious-1.5.1.tbz2;
-    sha256 = "1s32pdgx85qkrq15wwmvdw7wbcbxcf3nrhqxi6y72aijqm6fjwnz";
-  };
-
-  buildInputs = [pkgconfig libglade libmcs gettext dbus_glib];
-
-  propagatedBuildInputs = [glib gtk libmowgli libmcs];
-
-  NIX_LDFLAGS = "-rpath ${xlibs.libX11}/lib";
-
-  # Otherwise we barf with "libgcc_s.so.1 must be installed for
-  # pthread_cancel to work" on exit, as it tries to find libgcc_s
-  # dynamically.
-  dontPatchELF = true;
-
-  preBuild = ''
-    ensureDir $out/lib
-  '';
-
-  meta = {
-    description = "Audacious, a media player forked from the Beep Media Player, which was itself an XMMS fork";
-    homepage = http://audacious-media-player.org/;
-  };
-}

pkgs/applications/audio/audacious/plugins.nix

@@ -1,33 +0,0 @@
-{ stdenv, fetchurl, pkgconfig, audacious, dbus_glib, gettext
-, libmad, xlibs, alsaLib, taglib, libmpcdec, libogg, libvorbis
-, libcdio, libcddb, libxml2
-}:
-
-stdenv.mkDerivation {
-  name = "audacious-plugins-1.5.1";
-  
-  src = fetchurl {
-    url = http://distfiles.atheme.org/audacious-plugins-1.5.1.tbz2;
-    sha256 = "1ki5bd50g4vi4d0qzxynyrgaq2n4cwhbsxln9rwk8ppphvk9pawc";
-  };
-
-  buildInputs = [
-    pkgconfig audacious dbus_glib gettext libmad
-    xlibs.libXcomposite alsaLib taglib libmpcdec
-    libogg libvorbis libcdio libcddb libxml2
-  ];
-
-  preBuild = ''
-    makeFlagsArray=(pluginlibdir=$out/lib/audacious)
-  '';
-
-  NIX_LDFLAGS = "-L${audacious}/lib/audacious"; # needed because we override pluginlibdir
-
-  # `--enable-amidiplug' is to prevent configure from looking in /proc/asound.
-  configureFlags = "--enable-amidiplug";
-  
-  meta = {
-    description = "Plugins for the Audacious media player";
-    homepage = http://audacious-media-player.org/;
-  };
-}

pkgs/top-level/all-packages.nix

@@ -6759,18 +6759,13 @@ let
     inherit (gnome) libgnomecanvas;
   };
 
-  audacious = import ../applications/audio/audacious/player.nix {
+  audacious = import ../applications/audio/audacious {
-    inherit fetchurl stdenv pkgconfig libmowgli libmcs gettext xlibs dbus_glib;
+    inherit fetchurl stdenv gettext pkgconfig libmowgli libmcs
-    inherit (gnome) libglade;
+      dbus_glib libxml2 libmad xlibs alsaLib libogg libvorbis libcdio
+      libcddb flac;
     inherit (gtkLibs) glib gtk;
   };
 
-  audacious_plugins = import ../applications/audio/audacious/plugins.nix {
-    inherit fetchurl stdenv pkgconfig audacious dbus_glib gettext
-      libmad xlibs alsaLib taglib libmpcdec libogg libvorbis
-      libcdio libcddb libxml2;
-  };
-
   audacity = import ../applications/audio/audacity {
     inherit fetchurl stdenv gettext pkgconfig zlib perl intltool libogg
       libvorbis libmad;

pkgs/top-level/release.nix

@@ -16,7 +16,6 @@ with (import ./release-lib.nix);
   aterm25 = all;
   aterm28 = all;
   audacious = linux;
-  audacious_plugins = linux;
   autoconf = all;
   automake110x = all;
   automake111x = all;