graphite: 1.0.2 -> 1.1.3 & moved dependencies to python-modules (#44276)

Fixes #30891

* Upgrade `graphite-web`, `carbon` and `whisper` from 1.0.2 -> 1.1.3.

* Replaced the deprecated `pythonPackages.graphite_influxdb` with
  `pythonPackages.influxgraph.`

* Renamed `pythonPackages.graphite_web` to `pythonPackages.graphite-web`
  to be consistent with the Python package name.

* Replaced the unmaintained `pythonPackages.graphite_pager` with
  `pythonPackages.graphitepager`

* Moved all new packages from `python-packages.nix` to
  `pkgs/development/python-modules`

pkgs/development/python-modules/carbon/default.nix

@@ -0,0 +1,24 @@
+{ stdenv, buildPythonPackage, fetchPypi, isPy3k
+, twisted, whisper, txamqp, cachetools, urllib3
+}:
+
+buildPythonPackage rec {
+  pname = "carbon";
+  version = "1.1.3";
+
+  disabled = isPy3k;
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "1s7327p30w4l9ak4gc7m5ga521233179n2lr3j0ggfbmfhd6blky";
+  };
+
+  propagatedBuildInputs = [ twisted whisper txamqp cachetools urllib3 ];
+
+  meta = with stdenv.lib; {
+    homepage = http://graphite.wikidot.com/;
+    description = "Backend data caching and persistence daemon for Graphite";
+    maintainers = with maintainers; [ rickynils offline basvandijk ];
+    license = licenses.asl20;
+  };
+}

pkgs/development/python-modules/graphite-web/default.nix

@@ -0,0 +1,54 @@
+{ stdenv, buildPythonPackage, fetchPypi, isPy3k, which
+, django, django_tagging, whisper, pycairo, cairocffi, ldap, memcached, pytz, urllib3, scandir
+}:
+if django.version != "1.8.18"
+|| django_tagging.version != "0.4.3"
+then throw "graphite-web should be build with django_1_8 and django_tagging_0_4_3"
+else buildPythonPackage rec {
+  pname = "graphite-web";
+  version = "1.1.3";
+
+  disabled = isPy3k;
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "0nvyq1859abdch2l90avsjk9vb03s7wgxgrjsqvjhf2b9c1ncsfh";
+  };
+
+  propagatedBuildInputs = [
+    django django_tagging whisper pycairo cairocffi
+    ldap memcached pytz urllib3 scandir
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/run-graphite-devel-server.py \
+      --prefix PATH : ${which}/bin
+  '';
+
+  preConfigure = ''
+    # graphite is configured by storing a local_settings.py file inside the
+    # graphite python package. Since that package is stored in the immutable
+    # Nix store we can't modify it. So how do we configure graphite?
+    #
+    # First of all we rename "graphite.local_settings" to
+    # "graphite_local_settings" so that the settings are not looked up in the
+    # graphite package anymore. Secondly we place a directory containing a
+    # graphite_local_settings.py on the PYTHONPATH in the graphite module
+    # <nixpkgs/nixos/modules/services/monitoring/graphite.nix>.
+    substituteInPlace webapp/graphite/settings.py \
+      --replace "graphite.local_settings" " graphite_local_settings"
+
+    substituteInPlace webapp/graphite/settings.py \
+      --replace "join(WEBAPP_DIR, 'content')" "join('$out', 'webapp', 'content')"
+  '';
+
+  # error: invalid command 'test'
+  doCheck = false;
+
+  meta = with stdenv.lib; {
+    homepage = http://graphite.wikidot.com/;
+    description = "Enterprise scalable realtime graphing";
+    maintainers = with maintainers; [ rickynils offline basvandijk ];
+    license = licenses.asl20;
+  };
+}

pkgs/development/python-modules/graphite_beacon/default.nix

@@ -0,0 +1,25 @@
+{ stdenv, buildPythonPackage, fetchPypi
+, tornado, pyyaml, funcparserlib
+}:
+buildPythonPackage rec {
+  pname = "graphite_beacon";
+  version = "0.27.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "03bp4wyfn3xhcqyvs5hnk1n87m4smsmm1p7qp459m7j8hwpbq2ks";
+  };
+
+  propagatedBuildInputs = [ tornado pyyaml funcparserlib ];
+
+  postPatch = ''
+    substituteInPlace requirements.txt --replace "==" ">="
+  '';
+
+  meta = with stdenv.lib; {
+    description = "A simple alerting application for Graphite metrics";
+    homepage = https://github.com/klen/graphite-beacon;
+    maintainers = [ maintainers.offline ];
+    license = licenses.mit;
+  };
+}

pkgs/development/python-modules/graphitepager/default.nix

@@ -0,0 +1,32 @@
+{ stdenv, buildPythonPackage, fetchPypi
+, jinja2, markupsafe, pagerduty, pushbullet, python_magic, python-simple-hipchat
+, pyyaml, redis, requests, six, websocket_client, nose
+}:
+buildPythonPackage rec {
+  pname = "graphitepager";
+  version = "0.2.11";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "0v3g1qcgnkpgjzh6phnv13lnk8qjrcs9sq2qg6k0dk5ik31jfk3d";
+  };
+
+  propagatedBuildInputs = [
+    jinja2 markupsafe pagerduty pushbullet python_magic python-simple-hipchat
+    pyyaml redis requests six websocket_client
+  ];
+
+  postPatch = ''
+    substituteInPlace requirements.txt --replace "==" ">="
+  '';
+
+  checkInputs = [ nose ];
+  checkPhase = "nosetests";
+
+  meta = with stdenv.lib; {
+    description = "A simple alerting application for Graphite metrics";
+    homepage = https://github.com/seatgeek/graphite-pager;
+    maintainers = with maintainers; [ offline basvandijk ];
+    license = licenses.bsd2;
+  };
+}

pkgs/development/python-modules/influxgraph/default.nix

@@ -0,0 +1,30 @@
+{ stdenv, buildPythonPackage, fetchPypi, isPy3k
+, influxdb, graphite_api, memcached, gnugrep
+}:
+
+buildPythonPackage rec {
+  pname = "influxgraph";
+  version = "1.5.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "0l33sfwdh4bfprmzp2kx0d9098g6yxbnhyyx9qr3kzczpm0jg9vy";
+  };
+
+  patchPhase = stdenv.lib.optionalString isPy3k ''
+    sed 's/python-memcached/python3-memcached/' \
+      -i ./influxgraph.egg-info/requires.txt    \
+      -i ./setup.py
+  '';
+
+  propagatedBuildInputs = [ influxdb graphite_api memcached ];
+
+  passthru.moduleName = "influxgraph.InfluxDBFinder";
+
+  meta = with stdenv.lib; {
+    description = "InfluxDB storage plugin for Graphite-API";
+    homepage = https://github.com/InfluxGraph/influxgraph;
+    license = licenses.asl20;
+    maintainers = with maintainers; [ basvandijk ];
+  };
+}

pkgs/development/python-modules/whisper/default.nix

@@ -0,0 +1,20 @@
+{ stdenv, buildPythonPackage, fetchPypi, six }:
+
+buildPythonPackage rec {
+  pname = "whisper";
+  version = "1.1.3";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "1ahzsxk52ws8k3kdq52qbsbsx2r9z350j8gg9adw4x5fjwksz4r8";
+  };
+
+  propagatedBuildInputs = [ six ];
+
+  meta = with stdenv.lib; {
+    homepage = http://graphite.wikidot.com/;
+    description = "Fixed size round-robin style database";
+    maintainers = with maintainers; [ rickynils offline basvandijk ];
+    license = licenses.asl20;
+  };
+}