* Linux 2.6.20.

svn path=/nixpkgs/trunk/; revision=7879

pkgs/os-specific/linux/kernel/linux-2.6.20.nix

@@ -0,0 +1,48 @@
+{ stdenv, fetchurl, perl, mktemp, module_init_tools
+
+  # A list of patches to apply to the kernel.  Each element of this list
+  # should be an attribute set {name, patch} where `name' is a
+  # symbolic name and `patch' is the actual patch.  The patch may
+  # optionally be compressed with gzip or bzip2.
+, kernelPatches ? []
+}:
+
+assert stdenv.system == "i686-linux" || stdenv.system == "x86_64-linux";
+
+let lib = import ../../../lib; in
+
+stdenv.mkDerivation {
+  name = "linux-2.6.20";
+  builder = ./builder.sh;
+  
+  src = fetchurl {
+    url = http://ftp.nl.kernel.org/pub/linux/kernel/v2.6/linux-2.6.20.tar.bz2;
+    sha256 = "0n455dyvmbs9l0m3hll2rilyrj8gsqqablrhnh1jw9vxmjhss51c";
+  };
+  
+  patches = map (p: p.patch) kernelPatches;
+  extraConfig = lib.concatStrings (map (p: "\n" + p.extraConfig + "\n") kernelPatches);
+
+  config =
+    if stdenv.system == "i686-linux" then ./config-2.6.20-i686-smp else
+    if stdenv.system == "x86_64-linux" then ./config-2.6.20-x86_64-smp else
+    abort "No kernel configuration for your platform!";
+  
+  buildInputs = [perl mktemp];
+  
+  arch =
+    if stdenv.system == "i686-linux" then "i386" else
+    if stdenv.system == "x86_64-linux" then "x86_64" else
+    abort "";
+
+  inherit module_init_tools;
+
+  meta = {
+    description =
+      "The Linux kernel" +
+      (if kernelPatches == [] then "" else
+        " (with patches: "
+        + lib.concatStrings (lib.intersperse ", " (map (x: x.name) kernelPatches))
+        + ")");
+  };
+}

pkgs/top-level/all-packages.nix

@@ -2193,7 +2193,7 @@ rec {
     modules = [];
   };
 
-  kernel = kernel_2_6_19;
+  kernel = kernel_2_6_20;
 
   kernel_2_6_19 = import ../os-specific/linux/kernel/linux-2.6.19.nix {
     inherit fetchurl stdenv perl mktemp module_init_tools;
@@ -2221,6 +2221,28 @@ rec {
     ];
   };
 
+  kernel_2_6_20 = import ../os-specific/linux/kernel/linux-2.6.20.nix {
+    inherit fetchurl stdenv perl mktemp module_init_tools;
+    kernelPatches = [
+      { name = "skas-2.6.20-v9-pre9";
+        patch = fetchurl {
+          url = http://www.user-mode-linux.org/~blaisorblade/patches/skas3-2.6/skas-2.6.20-v9-pre9/skas-2.6.20-v9-pre9.patch.bz2;
+          md5 = "02e619e5b3aaf0f9768f03ac42753e74";
+        };
+        extraConfig =
+          "CONFIG_PROC_MM=y\n" +
+          "# CONFIG_PROC_MM_DUMPABLE is not set\n";
+      }
+      { name = "fbsplash-0.9.2-r5-2.6.20-rc6";
+        patch = fetchurl {
+          url = http://dev.gentoo.org/~spock/projects/gensplash/archive/fbsplash-0.9.2-r5-2.6.20-rc6.patch;
+          sha256 = "11v4f85f4jnh9sbhqcyn47krb7l1czgzjw3w8wgbq14jm0sp9294";
+        };
+        extraConfig = "CONFIG_FB_SPLASH=y";
+      }
+    ];
+  };
+
   libselinux = import ../os-specific/linux/libselinux {
     inherit fetchurl stdenv libsepol;
   };