# Package Notes

This chapter contains information about how to use and maintain the Nix expressions for a number of specific packages, such as the Linux kernel or X.org.

## Linux kernel

The Nix expressions to build the Linux kernel are in `pkgs/os-specific/linux/kernel`.

The function that builds the kernel has an argument `kernelPatches` which should be a list of `{name, patch, extraConfig}` attribute sets, where `name` is the name of the patch (which is included in the kernel’s `meta.description` attribute), `patch` is the patch itself (possibly compressed), and `extraConfig` (optional) is a string specifying extra options to be concatenated to the kernel configuration file (`.config`).

The kernel derivation exports an attribute `features` specifying whether optional functionality is or isn’t enabled. This is used in NixOS to implement kernel-specific behaviour. For instance, if the kernel has the `iwlwifi` feature (i.e. has built-in support for Intel wireless chipsets), then NixOS doesn’t have to build the external `iwlwifi` package:

    modulesTree = [kernel]
      ++ pkgs.lib.optional (!kernel.features ? iwlwifi) kernelPackages.iwlwifi
      ++ ...;

How to add a new (major) version of the Linux kernel to Nixpkgs:

1. Copy the old Nix expression (e.g. `linux-2.6.21.nix`) to the new one (e.g. `linux-2.6.22.nix`) and update it.

2. Add the new kernel to `all-packages.nix` (e.g., create an attribute `kernel_2_6_22`).

3. Now we’re going to update the kernel configuration. First unpack the kernel. Then for each supported platform (`i686`, `x86_64`, `uml`) do the following:

   1. Make an copy from the old config (e.g. `config-2.6.21-i686-smp`) to the new one (e.g. `config-2.6.22-i686-smp`).

   2. Copy the config file for this platform (e.g. `config-2.6.22-i686-smp`) to `.config` in the kernel source tree.

   3. Run `make oldconfig ARCH={i386,x86_64,um}` and answer all questions. (For the uml configuration, also add `SHELL=bash`.) Make sure to keep the configuration consistent between platforms (i.e. don’t enable some feature on `i686` and disable it on `x86_64`).

   4. If needed you can also run `make menuconfig`:

          $ nix-env -i ncurses
          $ export NIX_CFLAGS_LINK=-lncurses
          $ make menuconfig ARCH=arch

   5. Copy `.config` over the new config file (e.g. `config-2.6.22-i686-smp`).

4. Test building the kernel: `nix-build -A kernel_2_6_22`. If it compiles, ship it! For extra credit, try booting NixOS with it.

5. It may be that the new kernel requires updating the external kernel modules and kernel-dependent packages listed in the `linuxPackagesFor` function in `all-packages.nix` (such as the NVIDIA drivers, AUFS, etc.). If the updated packages aren’t backwards compatible with older kernels, you may need to keep the older versions around.

## X.org

The Nix expressions for the X.org packages reside in `pkgs/servers/x11/xorg/default.nix`. This file is automatically generated from lists of tarballs in an X.org release. As such it should not be modified directly; rather, you should modify the lists, the generator script or the file `pkgs/servers/x11/xorg/overrides.nix`, in which you can override or add to the derivations produced by the generator.

The generator is invoked as follows:

    $ cd pkgs/servers/x11/xorg
    $ cat tarballs-7.5.list extra.list old.list \
      | perl ./generate-expr-from-tarballs.pl

For each of the tarballs in the `.list` files, the script downloads it, unpacks it, and searches its `configure.ac` and `*.pc.in` files for dependencies. This information is used to generate `default.nix`. The generator caches downloaded tarballs between runs. Pay close attention to the `NOT FOUND: name` messages at the end of the run, since they may indicate missing dependencies. (Some might be optional dependencies, however.)

A file like `tarballs-7.5.list` contains all tarballs in a X.org release. It can be generated like this:

    $ export i="mirror://xorg/X11R7.4/src/everything/"
    $ cat $(PRINT_PATH=1 nix-prefetch-url $i | tail -n 1) \
      | perl -e 'while (<>) { if (/(href|HREF)="([^"]*.bz2)"/) { print "$ENV{'i'}$2\n"; }; }' \
      | sort > tarballs-7.4.list

`extra.list` contains libraries that aren’t part of X.org proper, but are closely related to it, such as `libxcb`. `old.list` contains some packages that were removed from X.org, but are still needed by some people or by other packages (such as `imake`).

If the expression for a package requires derivation attributes that the generator cannot figure out automatically (say, `patches` or a `postInstall` hook), you should modify `pkgs/servers/x11/xorg/overrides.nix`.

## Eclipse

The Nix expressions related to the Eclipse platform and IDE are in `pkgs/applications/editors/eclipse`.

Nixpkgs provides a number of packages that will install Eclipse in its various forms. These range from the bare-bones Eclipse Platform to the more fully featured Eclipse SDK or Scala-IDE packages and multiple version are often available. It is possible to list available Eclipse packages by issuing the command:

    $ nix-env -f '<nixpkgs>' -qaP -A eclipses --description

Once an Eclipse variant is installed it can be run using the `eclipse` command, as expected. From within Eclipse it is then possible to install plugins in the usual manner by either manually specifying an Eclipse update site or by installing the Marketplace Client plugin and using it to discover and install other plugins. This installation method provides an Eclipse installation that closely resemble a manually installed Eclipse.

If you prefer to install plugins in a more declarative manner then Nixpkgs also offer a number of Eclipse plugins that can be installed in an Eclipse environment. This type of environment is created using the function `eclipseWithPlugins` found inside the `nixpkgs.eclipses` attribute set. This function takes as argument `{ eclipse, plugins ? [], jvmArgs ? [] }` where `eclipse` is a one of the Eclipse packages described above, `plugins` is a list of plugin derivations, and `jvmArgs` is a list of arguments given to the JVM running the Eclipse. For example, say you wish to install the latest Eclipse Platform with the popular Eclipse Color Theme plugin and also allow Eclipse to use more RAM. You could then add

    packageOverrides = pkgs: {
      myEclipse = with pkgs.eclipses; eclipseWithPlugins {
        eclipse = eclipse-platform;
        jvmArgs = [ "-Xmx2048m" ];
        plugins = [ plugins.color-theme ];
      };
    }

to your Nixpkgs configuration (`~/.config/nixpkgs/config.nix`) and install it by running `nix-env -f '<nixpkgs>' -iA myEclipse` and afterward run Eclipse as usual. It is possible to find out which plugins are available for installation using `eclipseWithPlugins` by running

    $ nix-env -f '<nixpkgs>' -qaP -A eclipses.plugins --description

If there is a need to install plugins that are not available in Nixpkgs then it may be possible to define these plugins outside Nixpkgs using the `buildEclipseUpdateSite` and `buildEclipsePlugin` functions found in the `nixpkgs.eclipses.plugins` attribute set. Use the `buildEclipseUpdateSite` function to install a plugin distributed as an Eclipse update site. This function takes `{ name, src }` as argument where `src` indicates the Eclipse update site archive. All Eclipse features and plugins within the downloaded update site will be installed. When an update site archive is not available then the `buildEclipsePlugin` function can be used to install a plugin that consists of a pair of feature and plugin JARs. This function takes an argument `{ name, srcFeature, srcPlugin }` where `srcFeature` and `srcPlugin` are the feature and plugin JARs, respectively.

Expanding the previous example with two plugins using the above functions we have

    packageOverrides = pkgs: {
      myEclipse = with pkgs.eclipses; eclipseWithPlugins {
        eclipse = eclipse-platform;
        jvmArgs = [ "-Xmx2048m" ];
        plugins = [
          plugins.color-theme
          (plugins.buildEclipsePlugin {
            name = "myplugin1-1.0";
            srcFeature = fetchurl {
              url = "http://…/features/myplugin1.jar";
              sha256 = "123…";
            };
            srcPlugin = fetchurl {
              url = "http://…/plugins/myplugin1.jar";
              sha256 = "123…";
            };
          });
          (plugins.buildEclipseUpdateSite {
            name = "myplugin2-1.0";
            src = fetchurl {
              stripRoot = false;
              url = "http://…/myplugin2.zip";
              sha256 = "123…";
            };
          });
        ];
      };
    }

## Elm

The Nix expressions for Elm reside in `pkgs/development/compilers/elm`. They are generated automatically by `update-elm.rb` script. One should specify versions of Elm packages inside the script, clear the `packages` directory and run the script from inside it. `elm-reactor` is special because it also has Elm package dependencies. The process is not automated very much for now -- you should get the `elm-reactor` source tree (e.g. with `nix-shell`) and run `elm2nix.rb` inside it. Place the resulting `package.nix` file into `packages/elm-reactor-elm.nix`.

## Interactive shell helpers

Some packages provide the shell integration to be more useful. But unlike other systems, nix doesn't have a standard share directory location. This is why a bunch `PACKAGE-share` scripts are shipped that print the location of the corresponding shared folder. Current list of such packages is as following:

- `autojump`: `autojump-share`

- `fzf`: `fzf-share`

E.g. `autojump` can then used in the .bashrc like this:

      source "$(autojump-share)/autojump.bash"

## Steam

### Steam in Nix

Steam is distributed as a `.deb` file, for now only as an i686 package (the amd64 package only has documentation). When unpacked, it has a script called `steam` that in ubuntu (their target distro) would go to `/usr/bin` . When run for the first time, this script copies some files to the user's home, which include another script that is the ultimate responsible for launching the steam binary, which is also in $HOME.

Nix problems and constraints:

- We don't have `/bin/bash` and many scripts point there. Similarly for `/usr/bin/python` .

- We don't have the dynamic loader in `/lib` .

- The `steam.sh` script in $HOME can not be patched, as it is checked and rewritten by steam.

- The steam binary cannot be patched, it's also checked.

The current approach to deploy Steam in NixOS is composing a FHS-compatible chroot environment, as documented here. This allows us to have binaries in the expected paths without disrupting the system, and to avoid patching them to work in a non FHS environment.

### How to play

For 64-bit systems it's important to have

    hardware.opengl.driSupport32Bit = true;

in your `/etc/nixos/configuration.nix`. You'll also need

    hardware.pulseaudio.support32Bit = true;

if you are using PulseAudio - this will enable 32bit ALSA apps integration. To use the Steam controller or other Steam supported controllers such as the DualShock 4 or Nintendo Switch Pro, you need to add

    hardware.steam-hardware.enable = true;

to your configuration.

### Troubleshooting

Steam fails to start. What do I do?

  Try to run

      strace steam

  to see what is causing steam to fail.
Using the FOSS Radeon or nouveau (nvidia) drivers

  - The `newStdcpp` parameter was removed since NixOS 17.09 and should not be needed anymore.

  - Steam ships statically linked with a version of libcrypto that conflics with the one dynamically loaded by radeonsi_dri.so. If you get the error

        steam.sh: line 713: 7842 Segmentation fault (core dumped)

    have a look at this pull request.
Java

  1. There is no java in steam chrootenv by default. If you get a message like

         /home/foo/.local/share/Steam/SteamApps/common/towns/towns.sh: line 1: java: command not found

     You need to add

          steam.override { withJava = true; };

     to your configuration.

### steam-run

The FHS-compatible chroot used for steam can also be used to run other linux games that expect a FHS environment. To do it, add

    pkgs.(steam.override {
              nativeOnly = true;
              newStdcpp = true;
            }).run

to your configuration, rebuild, and run the game with

    steam-run ./foo

## Emacs

### Configuring Emacs

The Emacs package comes with some extra helpers to make it easier to configure. `emacsWithPackages` allows you to manage packages from ELPA. This means that you will not have to install that packages from within Emacs. For instance, if you wanted to use `company`, `counsel`, `flycheck`, `ivy`, `magit`, `projectile`, and `use-package` you could use this as a `~/.config/nixpkgs/config.nix` override:

    {
      packageOverrides = pkgs: with pkgs; {
        myEmacs = emacsWithPackages (epkgs: (with epkgs.melpaStablePackages; [
          company
          counsel
          flycheck
          ivy
          magit
          projectile
          use-package
        ]));
      }
    }

You can install it like any other packages via `nix-env -iA myEmacs`. However, this will only install those packages. It will not `configure` them for us. To do this, we need to provide a configuration file. Luckily, it is possible to do this from within Nix! By modifying the above example, we can make Emacs load a custom config file. The key is to create a package that provide a `default.el` file in `/share/emacs/site-start/`. Emacs knows to load this file automatically when it starts.

    {
      packageOverrides = pkgs: with pkgs; rec {
        myEmacsConfig = writeText "default.el" ''
    ;; initialize package

    (require 'package)
    (package-initialize 'noactivate)
    (eval-when-compile
      (require 'use-package))

    ;; load some packages

    (use-package company
      :bind ("<C-tab>" . company-complete)
      :diminish company-mode
      :commands (company-mode global-company-mode)
      :defer 1
      :config
      (global-company-mode))

    (use-package counsel
      :commands (counsel-descbinds)
      :bind (([remap execute-extended-command] . counsel-M-x)
             ("C-x C-f" . counsel-find-file)
             ("C-c g" . counsel-git)
             ("C-c j" . counsel-git-grep)
             ("C-c k" . counsel-ag)
             ("C-x l" . counsel-locate)
             ("M-y" . counsel-yank-pop)))

    (use-package flycheck
      :defer 2
      :config (global-flycheck-mode))

    (use-package ivy
      :defer 1
      :bind (("C-c C-r" . ivy-resume)
             ("C-x C-b" . ivy-switch-buffer)
             :map ivy-minibuffer-map
             ("C-j" . ivy-call))
      :diminish ivy-mode
      :commands ivy-mode
      :config
      (ivy-mode 1))

    (use-package magit
      :defer
      :if (executable-find "git")
      :bind (("C-x g" . magit-status)
             ("C-x G" . magit-dispatch-popup))
      :init
      (setq magit-completing-read-function 'ivy-completing-read))

    (use-package projectile
      :commands projectile-mode
      :bind-keymap ("C-c p" . projectile-command-map)
      :defer 5
      :config
      (projectile-global-mode))
        '';
        myEmacs = emacsWithPackages (epkgs: (with epkgs.melpaStablePackages; [
          (runCommand "default.el" {} ''
    mkdir -p $out/share/emacs/site-lisp
    cp ${myEmacsConfig} $out/share/emacs/site-lisp/default.el
    '')
          company
          counsel
          flycheck
          ivy
          magit
          projectile
          use-package
        ]));
      };
    }

This provides a fairly full Emacs start file. It will load in addition to the user's presonal config. You can always disable it by passing `-q` to the Emacs command.

Sometimes `emacsWithPackages` is not enough, as this package set has some priorities imposed on packages (with the lowest priority assigned to Melpa Unstable, and the highest for packages manually defined in `pkgs/top-level/emacs-packages.nix`). But you can't control this priorities when some package is installed as a dependency. You can override it on per-package-basis, providing all the required dependencies manually - but it's tedious and there is always a possibility that an unwanted dependency will sneak in through some other package. To completely override such a package you can use `overrideScope'`.

    overrides = self: super: rec {
      haskell-mode = self.melpaPackages.haskell-mode;
      ...
    };
    ((emacsPackagesNgGen emacs).overrideScope' overrides).emacsWithPackages (p: with p; [
      # here both these package will use haskell-mode of our own choice
      ghc-mod
      dante
    ])

## Weechat

Weechat can be configured to include your choice of plugins, reducing its closure size from the default configuration which includes all available plugins. To make use of this functionality, install an expression that overrides its configuration such as

    weechat.override {configure = {availablePlugins, ...}: {
        plugins = with availablePlugins; [ python perl ];
      }
    }

If the `configure` function returns an attrset without the `plugins` attribute, `availablePlugins` will be used automatically.

The plugins currently available are `python`, `perl`, `ruby`, `guile`, `tcl` and `lua`.

The python and perl plugins allows the addition of extra libraries. For instance, the `inotify.py` script in weechat-scripts requires D-Bus or libnotify, and the `fish.py` script requires pycrypto. To use these scripts, use the plugin's `withPackages` attribute:

    weechat.override { configure = {availablePlugins, ...}: {
        plugins = with availablePlugins; [
                (python.withPackages (ps: with ps; [ pycrypto python-dbus ]))
            ];
        };
    }

In order to also keep all default plugins installed, it is possible to use the following method:

    weechat.override { configure = { availablePlugins, ... }: {
      plugins = builtins.attrValues (availablePlugins // {
        python = availablePlugins.python.withPackages (ps: with ps; [ pycrypto python-dbus ]);
      });
    }; }

WeeChat allows to set defaults on startup using the `--run-command`. The `configure` method can be used to pass commands to the program:

    weechat.override {
      configure = { availablePlugins, ... }: {
        init = ''
          /set foo bar
          /server add freenode chat.freenode.org
        '';
      };
    }

Further values can be added to the list of commands when running `weechat --run-command "your-commands"`.

Additionally it's possible to specify scripts to be loaded when starting `weechat`. These will be loaded before the commands from `init`:

    weechat.override {
      configure = { availablePlugins, ... }: {
        scripts = with pkgs.weechatScripts; [
          weechat-xmpp weechat-matrix-bridge wee-slack
        ];
        init = ''
          /set plugins.var.python.jabber.key "val"
        '':
      };
    }

In `nixpkgs` there's a subpackage which contains derivations for WeeChat scripts. Such derivations expect a `passthru.scripts` attribute which contains a list of all scripts inside the store path. Furthermore all scripts have to live in `$out/share`. An exemplary derivation looks like this:

    { stdenv, fetchurl }:

    stdenv.mkDerivation {
      name = "exemplary-weechat-script";
      src = fetchurl {
        url = "https://scripts.tld/your-scripts.tar.gz";
        sha256 = "...";
      };
      passthru.scripts = [ "foo.py" "bar.lua" ];
      installPhase = ''
        mkdir $out/share
        cp foo.py $out/share
        cp bar.lua $out/share
      '';
    }

## Citrix Receiver

The Citrix Receiver is a remote desktop viewer which provides access to XenDesktop installations.

### Basic usage

The tarball archive needs to be downloaded manually as the licenses agreements of the vendor need to be accepted first. This is available at the download page at citrix.com. Then run `nix-prefetch-url file://$PWD/linuxx64-$version.tar.gz`. With the archive available in the store the package can be built and installed with Nix.

Note: it's recommended to install `Citrix Receiver` using `nix-env -i` or globally to ensure that the `.desktop` files are installed properly into `$XDG_CONFIG_DIRS`. Otherwise it won't be possible to open `.ica` files automatically from the browser to start a Citrix connection.

### Custom certificates

The `Citrix Receiver` in `nixpkgs` trusts several certificates from the Mozilla database by default. However several companies using Citrix might require their own corporate certificate. On distros with imperative packaging these certs can be stored easily in `$ICAROOT`, however this directory is a store path in `nixpkgs`. In order to work around this issue the package provides a simple mechanism to add custom certificates without rebuilding the entire package using `symlinkJoin`:

    with import <nixpkgs> { config.allowUnfree = true; };
    let extraCerts = [ ./custom-cert-1.pem ./custom-cert-2.pem /* ... */ ]; in
    citrix_receiver.override {
      inherit extraCerts;
    }

## ibus-engines.typing-booster

This package is an ibus-based completion method to speed up typing.

### Activating the engine

IBus needs to be configured accordingly to activate `typing-booster`. The configuration depends on the desktop manager in use. For detailed instructions, please refer to the upstream docs.

On NixOS you need to explicitly enable `ibus` with given engines before customizing your desktop to use `typing-booster`. This can be achieved using the `ibus` module:

    { pkgs, ... }: {
      i18n.inputMethod = {
        enabled = "ibus";
        ibus.engines = with pkgs.ibus-engines; [ typing-booster ];
      };
    }

### Using custom hunspell dictionaries

The IBus engine is based on `hunspell` to support completion in many languages. By default the dictionaries `de-de`, `en-us`, `es-es`, `it-it`, `sv-se` and `sv-fi` are in use. To add another dictionary, the package can be overridden like this:

    ibus-engines.typing-booster.override {
      langs = [ "de-at" "en-gb" ];
    }

Note: each language passed to `langs` must be an attribute name in `pkgs.hunspellDicts`.

### Built-in emoji picker

The `ibus-engines.typing-booster` package contains a program named `emoji-picker`. To display all emojis correctly, a special font such as `noto-fonts-emoji` is needed:

On NixOS it can be installed using the following expression:

    { pkgs, ... }: {
      fonts.fonts = with pkgs; [ noto-fonts-emoji ];
    }