nixos-config/packages/local.nix

{ pkgs, lib, ... }:

let
  unstablePkgs = import <nixos-unstable> {};

in {
  nixpkgs.config.packageOverrides = pkgs: rec {

    letsencrypt-ca = import ./letsencrypt-ca.nix {
      stdenv = pkgs.stdenv;
      fetchurl = builtins.fetchurl;
    };

    minecraft-server_1_15_1 = pkgs.minecraft-server.overrideAttrs (oldAttrs: rec {
      version = "1.15.1";
      src = builtins.fetchurl {
        url = "https://launcher.mojang.com/v1/objects/4d1826eebac84847c71a77f9349cc22afd0cf0a1/server.jar";
        sha256 = "a0c062686bee5a92d60802ca74d198548481802193a70dda6d5fe7ecb7207993";
      };
    });

    minecraft-current = pkgs.minecraft.overrideAttrs (oldAttrs: rec {
      src = builtins.fetchurl {
        url = "https://launcher.mojang.com/download/Minecraft.tar.gz";
        sha256 = "1k9gf1v1law4kiz8f7i2fxkj5vq2cm37b3ys95zpyf4aiw5nzg33";
      };
    });

    # DON'T LEAVE THE HASH--Nix will think the package hasn't changed
    minecraft-server_1_16_1 = let
      version = "1.16.1";
      url = "https://launcher.mojang.com/v1/objects/a412fd69db1f81db3f511c1463fd304675244077/server.jar";
      sha256 = "0nwkdig6yw4cnm2ld78z4j4xzhbm1rwv55vfxz0gzhsbf93xb0i7";
    in (pkgs.minecraft-server.overrideAttrs (oldAttrs: rec {
      name = "minecraft-server-${version}";
      inherit version;
      src = pkgs.fetchurl {
        inherit url sha256;
      };
    }));

    minecraft-server_1_16_2 = let
      version = "1.16.2";
      url = "https://launcher.mojang.com/v1/objects/c5f6fb23c3876461d46ec380421e42b289789530/server.jar";
      sha256 = "0fbghwrj9b2y9lkn2b17id4ghglwvyvcc8065h582ksfz0zys0i9";
    in (pkgs.minecraft-server.overrideAttrs (oldAttrs: rec {
      name = "minecraft-server-${version}";
      inherit version;
      src = pkgs.fetchurl {
        inherit url sha256;
      };
    }));

    postgresql_11_gssapi = pkgs.postgresql_11.overrideAttrs (oldAttrs: rec {
      configureFlags = oldAttrs.configureFlags ++ [ "--with-gssapi" ];
      buildInputs = oldAttrs.buildInputs ++ [ pkgs.krb5 ];
    });

    postgresql_12_gssapi = pkgs.postgresql_12.overrideAttrs (oldAttrs: rec {
      configureFlags = oldAttrs.configureFlags ++ [ "--with-gssapi" ];
      buildInputs = oldAttrs.buildInputs ++ [ pkgs.krb5 ];
    });

    hll2380dw-cups = import ./hll2380dw-cups.nix {
      inherit (pkgs) stdenv fetchurl makeWrapper cups dpkg a2ps ghostscript gnugrep gnused coreutils file perl which;
    };

    backplane-dns = import ./backplane-dns.nix {
      pkgs = pkgs;
      stdenv = pkgs.stdenv;
      fetchgit = pkgs.fetchgit;
    };

    backplane-dns-client = import ./backplane-dns-client.nix {
      pkgs = pkgs;
      stdenv = pkgs.stdenv;
      fetchgit = pkgs.fetchgit;
      bundlerEnv = pkgs.bundlerEnv;
    };

    cl-gemini = import ./cl-gemini.nix {
      pkgs = pkgs;
      stdenv = pkgs.stdenv;
      fetchgit = pkgs.fetchgit;
    };

    fudo-service = import ./fudo-service.nix {
      fetchgit = pkgs.fetchgit;
      pkgs = pkgs;
    };

    google-photos-uploader = pkgs.buildGoModule rec {
      pname = "google-photos-uploader";
      version = "1.6.1";

      src = pkgs.fetchFromGitHub {
        owner = "int128";
        repo = "gpup";
        rev = "${version}";
        sha256 = "0zdkd5iwkp270p0810dijg25djkzrsdyqiqaqv6rzzgzj5d5pwhm";
      };

      modSha256 = "15ndc6jq51f9mz1v089416x2lxrifp3wglbxpff8b055jj07hbkw";

      subPackages = [ "." ];

      meta = with pkgs.lib; {
        description = "Google photos uploader, written in Go.";
        homepage = https://github.com/int128/gpup;
        license = licenses.asl20;
        platforms = platforms.linux ++ platforms.darwin;
      };
    };

    localLispPackages = import ./lisp {
      inherit lib;
      pkgs = unstablePkgs;
    };
  };
}